【U3D/Shader】07.透明效果

程序员文章站 2024-02-14 09:45:58

...

自我介绍

广东双非一本的大三小白，计科专业，想在制作毕设前夯实基础，毕设做出一款属于自己的游戏！

透明效果

实现透明效果，就要控制透明通道

unity中会有两种方法实现透明效果

透明度测试
透明度混合

unity里面，倘若场景中包含很多模型时，我们需要考虑他们的渲染顺序来得到正确的排序效果，这就需要

深度缓冲（z-buffer）：根据深度缓存中的值来判断该片元距离摄像机的距离
倘若A挡住B，我们先渲染A，在渲染B时因为深度测试的时候会判断出B离摄像机更远，就不会写入到颜色缓冲中了

但是！

要实现透明度混合时，我们一定要关闭深度写入

透明度测试（简单粗暴）：只要一个片元的透明度不满足条件（小于某个阈值），那么该片元将会被舍弃，而不会对颜色缓冲产生任何影响
透明度混合：实现真正的半透明效果，关闭深度写入，不能关闭深度测试
- 当使用透明度混合渲染时，先比较它的深度值与当前深度缓冲中的深度值，如果该深度值距离摄像机更远，就不进行混合操作（反之则混合），这意味着当一个不透明物体出现在一个透明物体前面，先渲染不透明物体，它仍然可以正常的遮挡住透明物体

unity shader的渲染顺序

解决渲染顺序的问题，unity提出了 渲染队列 这一解决方案

我们可以用SubShader的Queue标签来决定我们的模型将归于哪个渲染队列，索引号越小表示越早被渲染

透明度测试

主要是提供一个新的float变量与主纹理的透明通道值（r）进行比较来控制需要过滤掉的片元是否显示

Shader "Unlit/016"
{
     Properties
	{
		_MainTex("MainTex", 2D) = "white" {}
		_Diffuse("Diffuse", Color) = (1,1,1,1)
		_Cutoff("Alpha Cutoff", Range(0,1)) = 0.5	//决定我们调用clip进行透明度测试时使用的判断条件
	}

	SubShader
	{
		//透明度测试使用的渲染队列是 AlphaTest
		//"IgnoreProjector"="True" 意味着 这个shader不会受投影器（Projectors）影响
		Tags { "Queue"="AlphaTest" "IgnoreProjector"="True" }
		LOD 100

		Pass
		{
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			#include "UnityCG.cginc"
			#include "Lighting.cginc"

			sampler2D _MainTex;
			float4 _MainTex_ST;
			fixed4 _Diffuse;
			float _Cutoff;

			struct v2f
			{
				float4 vertex : SV_POSITION;
				fixed3 worldNormal: TEXCOORD0;
				float3 worldPos: TEXCOORD1;
				float2 uv : TEXCOORD2;
			};

			v2f vert (appdata_base v)
			{
				v2f o;
				o.vertex = UnityObjectToClipPos(v.vertex);
				o.worldNormal = UnityObjectToWorldNormal(v.normal);
				o.worldPos = mul(unity_ObjectToWorld, v.vertex);
				o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
				return o;
			}
			
			fixed4 frag (v2f i) : SV_Target
			{
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;

				fixed4 texColor = tex2D(_MainTex, i.uv);

				// clip((texColor.a - _Cutoff) < 0);	//与下面的判断一致
				if((texColor.a - _Cutoff)<0)
				{
					discard;
				}

				//漫反射
				fixed3 worldLightDir = UnityWorldSpaceLightDir(i.worldPos);
				fixed3 diffuse = _LightColor0.rgb * texColor.rgb * _Diffuse.rgb * (dot(worldLightDir,i.worldNormal) * 0.5 + 0.5);

				fixed3 color = ambient + diffuse;
				return fixed4(color,1);
			}
			ENDCG
		}
	}
	FallBack "Transparent/Cutout/VertexLit"
}

效果

【U3D/Shader】07.透明效果

可以看到透明效果非常极端

透明度混合

其实代码跟上面的都差不多，只是去掉了透明度测试的代码，设置该片元着色器返回值中的透明通道，但是在设置之前，必须进行相应的设置打开blend命令打开混合，不然修改透明通道中的值（r）并无任何效果

Shader "Unlit/017"
{
      Properties
	{
		_MainTex("MainTex", 2D) = "white" {}
		_Diffuse("Diffuse", Color) = (1,1,1,1)
		_AlphaScale("Alpha Scale", Range(0,1)) = 1
	}

	SubShader
	{
		// "Queue"="Transparent" 这是透明度混合使用的渲染队列
		//"IgnoreProjector"="True" 意味着这个shader不会受投影器（projector）的影响
		//"RenderType"="Transparent" 让unity把这个shader归入到提前定义的 Transparent组
		Tags { "Queue"="Transparent" "IgnoreProjector"="True" "RenderType"="Transparent"}
		LOD 100

		ZWrite Off	//该pass关闭深度写入
		Blend SrcAlpha OneMinusSrcAlpha
		Pass
		{
			//"LightMode"="ForwardBase"：让unity能够按前向渲染路径的方式正确提供各个光照变量
			Tags{"LightMode"="ForwardBase"}
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			#include "UnityCG.cginc"
			#include "Lighting.cginc"

			sampler2D _MainTex;
			float4 _MainTex_ST;
			fixed4 _Diffuse;
			float _AlphaScale;

			struct v2f
			{
				float4 vertex : SV_POSITION;
				fixed3 worldNormal: TEXCOORD0;
				float3 worldPos: TEXCOORD1;
				float2 uv : TEXCOORD2;
			};

			v2f vert (appdata_base v)
			{
				v2f o;
				o.vertex = UnityObjectToClipPos(v.vertex);
				o.worldNormal = UnityObjectToWorldNormal( v.normal);
				o.worldPos = mul(unity_ObjectToWorld, v.vertex);
				o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
				return o;
			}
			
			fixed4 frag (v2f i) : SV_Target
			{
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;

				fixed4 texColor = tex2D(_MainTex, i.uv);

				//漫反射
				fixed3 worldLightDir = UnityWorldSpaceLightDir(i.worldPos);
				fixed3 diffuse = _LightColor0.rgb * texColor.rgb * _Diffuse.rgb * (dot(worldLightDir,i.worldNormal)*0.5+0.5);

				
				fixed3 color = ambient + diffuse;
				//只有使用Blend命令打开混合后，在这里设置的透明通道才有意义，不然这里的透明度不会对片元的透明效果有任何影响
				return fixed4(color, texColor.a * _AlphaScale);
			}
			ENDCG
		}
	}
	FallBack "Transparent/VertexLit"
}

【U3D/Shader】07.透明效果

这么一看好像实现了透明度混合了耶！实则不然，我们换一个更加复杂的模型

【U3D/Shader】07.透明效果

当模型本身有复杂的遮挡关系就会因为排序错误而产生错误的透明效果

这是因为关闭了深度写入，无法对模型进行像素级别的深度排序

优化（开启深度写入的半透明效果）

先看效果，这才是正确的半透明嘛！

【U3D/Shader】07.透明效果

实现原理：

开启两个pass来渲染模型：
- 第一个pass开启深度写入，但不输出颜色，把模型的深度值写入深度缓冲中
- 第二个pass进行正常的透明度混合
  - 因为第一个pass已经得到了逐像素的正确的深度信息，所以这个pass可以按照像素级别的深度排序结果进行透明渲染

Shader "Unlit/018"
{
         Properties
	{
		_MainTex("MainTex", 2D) = "white" {}
		_Diffuse("Diffuse", Color) = (1,1,1,1)
		_AlphaScale("Alpha Scale", Range(0,1)) = 1
	}

	SubShader
	{
		// "Queue"="Transparent" 这是透明度混合使用的渲染队列
		//"IgnoreProjector"="True" 意味着这个shader不会受投影器（projector）的影响
		//"RenderType"="Transparent" 让unity把这个shader归入到提前定义的 Transparent组
		Tags { "Queue"="Transparent" "IgnoreProjector"="True" "RenderType"="Transparent"}
		LOD 100

		//这个pass仅仅把模型的深度信息写入深度缓冲中，从而剔除模型中被自身遮挡的片元
		Pass
		{
			ZWrite On
			//意味着不写入任何颜色通道
			// ColorMask RGB | A | 0 | 其他R,G,B,A的组合
			ColorMask 0
		}

		Pass
		{
			Tags{"LightMode"="ForwardBase"}

			ZWrite Off
			Blend SrcAlpha OneMinusSrcAlpha
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			#include "UnityCG.cginc"
			#include "Lighting.cginc"

			sampler2D _MainTex;
			float4 _MainTex_ST;
			fixed4 _Diffuse;
			float _AlphaScale;

			struct v2f
			{
				float4 vertex : SV_POSITION;
				fixed3 worldNormal: TEXCOORD0;
				float3 worldPos: TEXCOORD1;
				float2 uv : TEXCOORD2;
			};

			v2f vert (appdata_base v)
			{
				v2f o;
				o.vertex = UnityObjectToClipPos(v.vertex);
				o.worldNormal = UnityObjectToWorldNormal(v.normal);
				o.worldPos = mul(unity_ObjectToWorld, v.vertex);
				o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
				return o;
			}
			
			fixed4 frag (v2f i) : SV_Target
			{
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;

				fixed4 texColor = tex2D(_MainTex, i.uv);

				//漫反射
				fixed3 worldLightDir = UnityWorldSpaceLightDir(i.worldPos);
				//fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
				fixed3 diffuse = _LightColor0.rgb * texColor.rgb * _Diffuse.rgb * (dot(worldLightDir,i.worldNormal)*0.5+0.5);

				
				fixed3 color = ambient + diffuse;
				return fixed4(color, texColor.a * _AlphaScale);
			}
			ENDCG
		}
	}
	FallBack "Transparent/VertexLit"
}

上一篇：【leetcode.347】前 K 个高频元素

下一篇： Unity Shader 两个关于下雨的效果分享

【U3D/Shader】07.透明效果

自我介绍

透明效果

但是！

unity shader的渲染顺序

透明度测试

透明度混合

优化（开启深度写入的半透明效果）

【U3D/Shader】07.透明效果

转载：Unity双面Shader 双面材质 支持透明效果

转载：Unity双面Shader 双面材质支持透明效果