再学 GDI+[11] DrawCurve - 绘制曲线

 

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ComCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    TrackBar1: TTrackBar;
    LabeledEdit1: TLabeledEdit;
    LabeledEdit2: TLabeledEdit;
    procedure FormMouseUp(Sender: TObject; Button: TMouseButton;
      Shift: TShiftState; X, Y: Integer);
    procedure FormPaint(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure TrackBar1Change(Sender: TObject);
    procedure LabeledEdit1Change(Sender: TObject);
    procedure LabeledEdit2Change(Sender: TObject);
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

uses GDIPOBJ, GDIPAPI;

var
  PtArr: array of TGPPoint;
  i: Integer = 0;
  tension: Single;  //因为我们要用到的曲度值要精确到小数，所以此变量为single类型

procedure TForm1.FormCreate(Sender: TObject);
begin
  Button1.Caption := '擦除';
  LabeledEdit1.EditLabel.Caption := '第几点开始';
  LabeledEdit2.EditLabel.Caption := '画几段';
  LabeledEdit1.Text := '0';
  LabeledEdit2.Text := '0';
  TrackBar1.ShowSelRange := False;   //这段代码可有可无，但加上这个我觉得跟踪条会更好看些
  TrackBar1.Min := -25;
  TrackBar1.Max := 35;
  TrackBar1.Position := 5;
end;

procedure TForm1.FormMouseUp(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
begin
  Inc(i);
  SetLength(PtArr, i);
  PtArr[i-1].X := X;
  PtArr[i-1].Y := Y;
  LabeledEdit2.Text := IntToStr(i-1);
  Text := IntToStr(i);
  Repaint;
end;

procedure TForm1.FormPaint(Sender: TObject);
var
  g: TGPGraphics;
  p: TGPPen;
  i,n1,n2: Integer;
begin
  Form1.DoubleBuffered:=True;  //双缓冲
  g := TGPGraphics.Create(Canvas.Handle);
  p := TGPPen.Create(aclRed, 2);
  g.Clear(aclWhite);

  n1 := StrToIntDef(LabeledEdit1.Text, 0);
  n2 := StrToIntDef(LabeledEdit2.Text, Length(PtArr)-1);
  g.SetSmoothingMode(SmoothingModeHighQuality); //设置高质量抗锯齿

  {第4，5，6参数为可选，第4参数是从第几点开始画，第5参数是画几段，
  第6参数为曲度值，这里是 0.5, 如果为 0 时曲线会转为直线段}
  g.DrawCurve(p, PGPPoint(PtArr), Length(PtArr), n1, n2, tension);  //画曲线

  p.SetWidth(1);
  p.SetColor(aclBlack);
  for i := 0 to Length(PtArr) - 1 do
    g.DrawEllipse(p, PtArr[i].X-2, PtArr[i].Y-2, 4, 4);

  g.Free;
  p.Free;
end;

procedure TForm1.LabeledEdit1Change(Sender: TObject);
var
  a,b: Integer;
begin        {看画曲线的第4，第5参数，也就是n1,n2，下面代码就是控制n1不能小0，
              因为不能从负数点开始画起，也不能大于（所画的点数-2），因为我们最起码要它画一段}
  a := StrToIntDef(LabeledEdit1.Text, 0);
  if (a < 0) or (a > Length(PtArr) - 2) then
    LabeledEdit1.Text := IntToStr(0);

  a := StrToIntDef(LabeledEdit1.Text, 0);
  b := StrToIntDef(LabeledEdit2.Text, 0);
  if a+b > Length(PtArr)-1 then           //如果n1,n2的和大于最后那一点的数值，那么就超出范围了
    LabeledEdit2.Text := IntToStr(Length(PtArr)-1-a);
  Repaint;
end;

procedure TForm1.LabeledEdit2Change(Sender: TObject);
var
  a,b: Integer;
begin
  a := StrToIntDef(LabeledEdit1.Text, 0);
  b := StrToIntDef(LabeledEdit2.Text, 0);
  if (b < 0) or (b >= Length(PtArr) - a) then   //画负数段和画超出范围的段数都不行的
    LabeledEdit2.Text := IntToStr(Length(PtArr)-1-a);
  Repaint;
end;

procedure TForm1.TrackBar1Change(Sender: TObject);
begin
  tension := TrackBar1.Position / 10;
  Repaint;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  i := 0;
  SetLength(PtArr, i);
  LabeledEdit1.Text:=IntToStr(i);   //既然所画的点被擦除了，那么这两个标签编辑框也应该清0了。
  LabeledEdit2.Text:=IntToStr(i);
  Repaint;
  Text := IntToStr(i);
end;

end.

转载于:https://www.cnblogs.com/keyvip/archive/2010/12/31/1922807.html