用批处理文件自动备份文件及文件夹，并自动删除n天前的文件

下是备份的批处理,添加到"计划任务"中,设定时间自动运行

@echo off
rem 格式化日期
rem date出来的日期是"2006-02-22 星期三"，不能直接拿来使用，所以应该先格式化一下
rem 变成我们想要的。date:~0,4的意思是从0开始截取4个字符
set d=%date:~0,4%%date:~5,2%%date:~8,2%
rem 设定压缩程序路径，这里用的是winrar的rar.exe进行打包的
set path=c:\program files\winrar
rem 设定要备份的目录
set srcdir=d:\databasc
rem 设定备份文件所在目录
set dstdir=e:\temp\backup
rem 设定备份文件的前缀,目前为temp,前缀为backup
set webprefix=
rem 如果文件不存在,开始备份
if not exist %dstdir%%webprefix%%d%.rar start rar a -r %dstdir%%webprefix%%d%.rar %srcdir%
@echo on

以下是删除n天前备份文件的批处理,注:在windows2003下,如xp下因为没有forfiles.exe,未测试拷贝2003的文件到xp的system32目录
删除在c盘backup目录下最后修改日期在10天前的文件
=================================================================================
forfiles /p "c:\backup" /d -10 /c "cmd /c echo deleting @file ... && del /f @path"
=================================================================================
以下是复制某天前文件到其它位置的批处理
要把在c盘根目录下最后修改日期大于或等于2007年7月1日的文件复制到d盘根目录下
=================================================================================
forfiles /p "c:\" /d "2007-7-1" /c "cmd /c copy @path d:\"
windows server 2003内置的命令行文件，适合于xp以上系统
示例：
forfiles /m *.bkf /d -28 /c "cmd /c del @file /f"
删除当前目录下28天以前的扩展名为bkf文件（以当前系统时间为基准）
forfiles 自动删除7天前文件 delete
2008-09-12 15:01
用forfiles.exe试试。
forfiles /p "d:\test" /s /m *.* /d -7 /c "cmd /c del @path"
做成批处理文件，bat文件与forfiles.exe同一目录下，建一个bat文件的快捷方式在启动。
d:\test换成你要的目录路径。日期是指修改的日期。
附上forfiles.exe及帮助。
删除所有的空目录(以删除d:\test目录下为例)
dir /ad/b/s d:\test\ |sort /r >d:\kill.txt
for /f "tokens=*" %%i in (d:\kill.txt) do rd "%%i"
del d:\kill.txt
把以下复制到bat文件中。
@echo off
forfiles /p "d:\test" /s /m *.* /d -7 /c "cmd /c del @path"
dir /ad/b/s d:\test\ |sort /r >d:\kill.txt
for /f "tokens=*" %%i in (d:\kill.txt) do rd "%%i"
del d:\kill.txt
先删过期文件，再删所有的空目录
如果操作系统是 windows server 2003 那就好办了，因为它有一个forfiles命令能够查找满足指定条件的文件，下面是这个命令的用法。
forfiles /p <目标目录名> /d <天数> /c <执行的命令>
看看列出的三个参数都有什么用处：
/p 指定了要在哪个目录里查找文件，默认是当前工作目录。
/d 指定一个日期或天数，用于比较文件的最后修改日期是否符合条件。
/c 对每个找到的文件执行的命令。
例1.要把在c盘根目录下最后修改日期大于或等于2007年7月1日的文件复制到d盘根目录下：
forfiles /p "c:\" /d "2007-7-1" /c "cmd /c copy @path d:\"
例2.删除在c盘backup目录下最后修改日期在10天前的文件：
forfiles /p "c:\backup" /d -10 /c "cmd /c echo deleting @file ... && del /f @path"
先看删除文件的代码
forfiles /p 包含要删除文件的完整路径（如：f:\logfiles) /m *.log -d -7 /c "cmd /c del /f @path"
解释一下相关参数及命令
/p <path> ： 指定开始搜索文件的位置，如果不指定则默认为当前目录。
/m <searchmask> ： 文件查找所使用的通配符如代码中的"*.log"则为所有日志文件，当然也可以指定诸如"manmee_*.log"这样以manmee开头的所有日志文件。如果不指定此参数则默认为"*.*"。
/d [{+|-}][{<date>|<days>}] ： 指定想选择文件的最后修改时间，上文中用了 "/d -7" 表示所有以当天为基础，7天以前的文件。当然这里还可以指定具体时间，例如："/d -08/18/2009"这样所有早于2009年8月18日的文件。注意指定的时间必须是"mm/dd/yyyy"的格式。
/c 对所有文件以此执行指定的命令，命令体须在双引号(")内，默认是"cmd /c echo @file"。上文中用到的是"cmd /c del /f @path"删除指定文件。（这里的@file 和 @path 为变量，下文中将解释。）
下面说一下上文中用到的参数：
@path ： 表示文件的完整的路径。
@file ： 表示文件名称。
其他参数的详细介绍点击这里。
接下来我们看看删除文件夹的操作，如果你看了上面的介绍，相信这命令你一看就能看懂。
forfiles /p 包含文件夹的路径(如：f:\) /m 文件夹名称(如：logfiles) -d 0 /c "cmd /c if @isdir == true rd /s/q @path"
注意这里的"包含文件夹的路径"不能包含要删除的文件夹，如以上代码所表示的就是，在f盘中查找名为logfiles的文件或文件夹（不能指定查找文件夹，不过在删除时我们做了判断）。
还有就是这里出现了一个新的参数"@isdir"他用于判断当前文件类型是否是"文件夹类型"，如果是则为true否则为false。
相信到这大家就明白了，最后再将代码保存为批处理文件，然后加入计划任务定期执行即可。
看了上面的例子，觉得在 windows server 2003 下面要删除老文件很简单吧。
但如果操作系统是 windows 2000/xp 就比较麻烦，因为它们没有forfiles命令，只能靠自己写批处理来实现了。
下面是我写的批处理文件内容：

@echo off
rem ******************************
rem * 按时间删除文件目录的批处理 *
rem ******************************
rem 设置临时目录的路径
set tempdir=%tmp%\remove_%date:~0,10%
if not exist %tempdir% md %tempdir%
rem 设置处理日期的脚本文件的路径
set scriptfile=%tempdir%\get_date.vbs
rem 获得要保留的天数
set days=%~1
if "%days%" == "" goto printusage
rem 获得目标目录的路径
set dirpath=%~2
if "%dirpath%" == "" set dirpath=.
rem 获得要操作的文件形式
set filespec=%~3
if "%filespec%" == "" set filespec=*.*
rem 生成计算日期的脚本文件并获得删除的截止日期
echo d=date()-%1 > %scriptfile%
echo s=right("0000" ^& year(d),4) ^& "-" ^& right("00" ^& month(d),2) ^& "-" ^& right("00" ^& day(d),2) >> %scriptfile%
echo wscript.echo s >> %scriptfile%
for /f %%i in ('cscript /nologo %scriptfile%') do set lastdate=%%i
rem 处理目标目录里的每个对象
for /f "tokens=1,2,3* delims=<> " %%i in ('dir "%dirpath%\%filespec%" /a /-c /tc') do call :proc "%%i" "%%j" "%%k" "%%l"
goto :done
rem 处理目标目录里对象的过程
:proc
rem 获得对象的创建日期并判断是否为有效格式
set filedate=%~1
echo %filedate% | findstr "[0-9][0-9][0-9][0-9]-[0-9][0-9]-[0-9][0-9]" > nul
if errorlevel 1 goto end
rem 获得对象的类型
set filetype=%~3
if "%filetype%" == "" goto end
rem 获得对象的名称
set filename=%~4
if "%filename%" == "" goto end
if "%filename%" == "." goto end
if "%filename%" == ".." goto end
if "%filename%" == "字节" goto end
if "%filename%" == "可用字节" goto end
rem 判断对象日期是否小于或等于删除的截止日期
if "%filedate:~0,10%" leq "%lastdate%" (
echo deleting "%filename%" ...
if "%filetype%" == "dir" ( rd /s /q "%dirpath%\%filename%" ) else ( del /q /f "%dirpath%\%filename%" )
)
goto end
:error
echo an error occurred during backuping.
:done
rd /s /q %tempdir%
goto end
:printusage
echo usage: %0 ^<days^> [work directory] [target file specification (can include wildcards)]
goto end
:end

主要是利用windows的脚本功能来计算要删除文件的截止日期，然后for加dir命令来提取文件的日期进行判断。
关于forfiles和for的详细信息，可以在windows的帮助与支持中找到。