vbs脚本实现批量转换文件编码
最近需要使用sourceinsight查看分析在linux系统下开发的项目代码，我们知道linux系统中文本文件默认编码格式是utf-8，而windows中文系统中的默认编码格式是gb2312。系统内的编码格式有所区别倒无伤大雅，关键的是sourceinsight竟不支持utf-8，导致项目代码内的中文注释全部乱码！
既然sourceinsight不支持utf-8编码的文件，那我们就得想办法将utf-8的代码文件转化为gb2312编码的。首先想到的是到网上搜一下“批量编码转换工具”，结果下载后发现编码转换后的文件总是出现乱码，可能是工具的bug吧。既然不能使用工具转换，那就自己写一个程序进行编码转换，但是细想一下觉得c++/java的编码转换程序写起来又比较啰嗦，要是在linux下写一个shell脚本就能轻松搞定了。还好windows下有vbs脚本可以帮助我们轻松达到这个目的。
'-------------------------------------------------
'函数名称:readfile
'作用:利用adodb.stream对象来读取各种格式的文本文件
'-------------------------------------------------
function readfile(fileurl, charset)
dim str
set stm = createobject("adodb.stream")
stm.type = 2
stm.mode = 3
stm.charset = charset
stm.open
stm.loadfromfile fileurl
str = stm.readtext
stm.close
set stm = nothing
readfile = str
end function
我们使用readfile函数读取文件，其中fileurl指定文件的路径，charset指定文件的原始编码格式，使用adodb.stream对象读取文件内容到str。
'-------------------------------------------------
'函数名称:writetofile
'作用:利用adodb.stream对象来写入各种格式的文本文件
'-------------------------------------------------
function writetofile (fileurl, str, charset)
set stm = createobject("adodb.stream")
stm.type = 2
stm.mode = 3
stm.charset = charset
stm.open
stm.writetext str
stm.savetofile fileurl, 2
stm.flush
stm.close
set stm = nothing
end function
然后使用writetofile将str写回原文件fileurl，并设定新的编码charset。
'-------------------------------------------------
'函数名称:convertfile
'作用:将一个文件进行编码转换
'-------------------------------------------------
function convertfile(fileurl)
call writetofile(fileurl, readfile(fileurl, srccode), destcode)
end function
这样convertfile对上述两个函数封装，实现文件fileurl的编码转换，其中原始编码srccode与目的编码destcode为全局变量。
如果仅对一个文件进行编码转换，我们不必这么大费周章。我们希望能对任意的文件或文件夹内的所有文件进行编码转换，达到批量转换的目的。
'函数名称:convertdir
'作用:将任意目录内的文件进行编码转换
'-------------------------------------------------
function convertdir(dirurl)
if fs.fileexists(dirurl) then
call convertfile(dirurl)
else
call searchdir(dirurl)
end if
end function
函数convertdir对任意路径的文件/文件夹进行编码转换，使用scripting.filesystemobject对象的fileexists函数判断路径对应的是文件还是文件夹，如果是文件则直接调用convertfile进行编码转换，否则调用searchdir处理文件夹。
'-------------------------------------------------
'函数名称:searchdir
'作用:递归查找目录内的文件，进行编码转换
'-------------------------------------------------
function searchdir(path)
set folder = fs.getfolder(path)
set subfolders = folder.subfolders
set files = folder.files
for each i in files
call convertfile(i.path)
next
for each j in subfolders
call searchdir(j.path)
next
end function
函数searchdir是递归的，首先调用getfolder创建文件夹对象，然后取出文件夹内的子文件夹集合subfolders和子文件集合files。对于每个子文件，直接调用convertfile进行编码转换即可，而对于每个子文件夹，则递归调用searchdir重复处理。
'-------------------------------------------------
'设置编码：默认 utf-8 --> gb2312
'-------------------------------------------------
srccode="utf-8"
destcode="gb2312"
'-------------------------------------------------
'解析参数
'-------------------------------------------------
set fs = createobject("scripting.filesystemobject")
set objargs = wscript.arguments
if objargs.count>0 then
for i = 0 to objargs.count - 1
fileurl = objargs(i)
call convertdir(fileurl)
next
else
msgbox "没有文件/文件夹被拖入！"
wscript.quit
end if
msgbox "转换成功！"
最后通过解析脚本文件的参数，由于每个参数对应一个文件/文件夹的路径，将之传递给convertdir即可。这里默认的是将utf-8编码转化为gb2312编码，读者可以根据自身需要自行修改。
将上述代码保存为convertcode.vbs，只需要将任意多个文件选中拖动到该脚本文件上即可。或者使用命令行。
> convertcode.vbs [filepath]
需要注意的是文件编码是就地转换的，在转换之前最好将原文件/文件夹进行备份。
最后附上脚本文件的所有代码。
'/*===========================================================
' * intro 把要转换的多个文件/文件夹拖到该文件上即可
' * filename convertcode.vbs
' * author florian
' * version v1.0
' * lastmodify 2014-06-11 00:39:58
' *==========================================================*/
'-------------------------------------------------
'设置编码：默认 utf-8 --> gb2312
'-------------------------------------------------
srccode="utf-8"
destcode="gb2312"
'-------------------------------------------------
'解析参数
'-------------------------------------------------
set fs = createobject("scripting.filesystemobject")
set objargs = wscript.arguments
if objargs.count>0 then
for i = 0 to objargs.count - 1
fileurl = objargs(i)
call convertdir(fileurl)
next
else
msgbox "没有文件/文件夹被拖入！"
wscript.quit
end if
msgbox "转换成功！"
'-------------------------------------------------
'函数名称:convertdir
'作用:将任意目录内的文件进行编码转换
'-------------------------------------------------
function convertdir(dirurl)
if fs.fileexists(dirurl) then
call convertfile(dirurl)
else
call searchdir(dirurl)
end if
end function
'-------------------------------------------------
'函数名称:searchdir
'作用:递归查找目录内的文件，进行编码转换
'-------------------------------------------------
function searchdir(path)
set folder = fs.getfolder(path)
set subfolders = folder.subfolders
set files = folder.files
for each i in files
call convertfile(i.path)
next
for each j in subfolders
call searchdir(j.path)
next
end function
'-------------------------------------------------
'函数名称:convertfile
'作用:将一个文件进行编码转换
'-------------------------------------------------
function convertfile(fileurl)
call writetofile(fileurl, readfile(fileurl, srccode), destcode)
end function
'-------------------------------------------------
'函数名称:readfile
'作用:利用adodb.stream对象来读取各种格式的文本文件
'-------------------------------------------------
function readfile(fileurl, charset)
dim str
set stm = createobject("adodb.stream")
stm.type = 2
stm.mode = 3
stm.charset = charset
stm.open
stm.loadfromfile fileurl
str = stm.readtext
stm.close
set stm = nothing
readfile = str
end function
'-------------------------------------------------
'函数名称:writetofile
'作用:利用adodb.stream对象来写入各种格式的文本文件
'-------------------------------------------------
function writetofile (fileurl, str, charset)
set stm = createobject("adodb.stream")
stm.type = 2
stm.mode = 3
stm.charset = charset
stm.open
stm.writetext str
stm.savetofile fileurl, 2
stm.flush
stm.close
set stm = nothing
end functionview code