ARM芯片时钟

在芯片上不仅有CPU，还有各种外设，可以分为两部分，有AHB总线和APB总线。

所以引入三个时钟，CPU工作于Fclk，AHB总线工作于Hclk，慢速设备(外设总线)工作于Pclk。

可见时钟源有两个，晶振和引脚输入的时钟，有个选择器，由引脚OM[3:2]选择

2440由两个PLL（ Phase Locked Loops锁相环 ），一个生产时钟给CPU用的，一个生产时钟给USB用的。有电路图知OM2、OM3都是接地的，所以MPLL和UPLL都使用晶振作为时钟源。晶振的12M进来，经过MPLL和UPLL使用P、M、S三个参数来控制它输出多高的频率。经过PLL得到一个时钟，这个时钟会作为Fclk提供给CPU，在经过分频得到hclk和pclk。Fclk传给CPU，Hclk传给高速设备，Pclk传给低速设备。

一上电复位引脚要维持一段时间等待电源稳定，一上电Fclk已经起振了，但CPU还没有运行，复位引脚松开的时候CPU才运行。PLL锁存OM[3,2]的值，同时CPU开始运行。一旦设置PLL，这段时间是lock time，PLL没有起振，CPU停止。在锁定时间里PLL开始工作，CPU需要等PLL输出稳定的时钟。等lock time结束，Fclk就等于PLL输出的新的时钟了。

寄存器

LOCKTIME（LOCK TIME COUNT）寄存器：用于设置"Lock Time"的长度
MPULLCON（Main PLL Control）寄存器：用于设置FCLK与Fin的倍数
CLKDIVN（CLOCK DIVIDER CONTROL）寄存器：用于设置FCLK、HCLK、PCLK三者的比例
CAMDIVN寄存器

程序

实现：Fclk=400MHz，Hclk=100MHz，Pclk=50MHz。

如果HDIVN非0，CPU的总线模式应该从"fast bus mode"设置为"asynchronous bus mode"异步模式。
mrc p15,0,r0,c1,c0,0
orr r0,r0,#0xc0000000 //R1_nF:OR:R1_iA
mcr p15,0,r0,c1,c0,0

.text
.global _start
_start:
	/* 关闭看门狗 */
	ldr r0, =0x53000000
	ldr r1, =0
	str r1, [r0]

	/* 设置MPLL, FCLK : HCLK : PCLK = 400m : 100m : 50m */
	/* LOCKTIME(0x4C000000) = 0xFFFFFFFF */
	ldr r0, =0x4C000000
	ldr r1, =0xFFFFFFFF
	str r1, [r0]

	/* CLKDIVN(0x4C000014) = 0X5, tFCLK:tHCLK:tPCLK = 1:4:8  */
	ldr r0, =0x4C000014
	ldr r1, =0x5
	str r1, [r0]

	/* 设置CPU工作于异步模式 */
	mrc p15,0,r0,c1,c0,0
	orr r0,r0,#0xc0000000   //R1_nF:OR:R1_iA
	mcr p15,0,r0,c1,c0,0

	/* 设置MPLLCON(0x4C000004) = (92<<12)|(1<<4)|(1<<0) 
	 *  m = MDIV+8 = 92+8=100
	 *  p = PDIV+2 = 1+2 = 3
	 *  s = SDIV = 1
	 *  FCLK = 2*m*Fin/(p*2^s) = 2*100*12/(3*2^1)=400M
	 */
	ldr r0, =0x4C000004
	ldr r1, =(92<<12)|(1<<4)|(1<<0)
	str r1, [r0]

	/* 一旦设置PLL, 就会锁定lock time直到PLL输出稳定
	 * 然后CPU工作于新的频率FCLK
	 */
	
	/* 设置内存: sp 栈 */
	/* 分辨是nor/nand启动
	 * 写0到0地址, 再读出来
	 * 如果得到0, 表示0地址上的内容被修改了, 它对应ram, 这就是nand启动
	 * 否则就是nor启动
	 */
	mov r1, #0
	ldr r0, [r1] /* 读出原来的值备份 */
	str r1, [r1] /* 0->[0] */ 
	ldr r2, [r1] /* r2=[0] */
	cmp r1, r2   /* r1==r2? 如果相等表示是NAND启动 */
	ldr sp, =0x40000000+4096 /* 先假设是nor启动 */
	moveq sp, #4096  /* nand启动 */
	streq r0, [r1]   /* 恢复原来的值 */
	
	bl main

halt:
	b halt