Android rom解包打包工具

emmc主要是针对手机和平板电脑等产品的内嵌式存储器，由于其在封装中集成了一个控制器，且提供标准接口并管理闪存等优势，越来越受到android手机厂商的青睐，以emmc为存储设备的android手机，其文件系统（system、data分区）一般采用ext4格式。如小米手机的线刷包：

一.img解包

之前我在修改小米桌面中介绍过利用rom助手解包。

这里介绍另一个更方便实用的工具：windows平台的ext4_unpacker。

直接选择需要解压的img镜像文件，然后extract所有文件即可。同样，解压出来后可对rom进行精简，删除一些不需要的app。

二.img打包

这里利用make_ext4fs来对解压出来的文件进行打包。

使用说明：将下载下来的make_ext4fs.exe拷贝到c:\windows目录下，其他dll文件，拷贝到c:\windows\system32目录下。

主要参数说明：

-l <limit size>:表示最大的文件大小，受限于system或data分区的大小。

-a <system/data>:表示android的mount点，将img文件系统挂在到安卓手机的system/data文件夹下。

-s file_contexts:表示sepolicy的file_contexts，5.0及以上安卓系统存在file_contexts文件，该文件是对selinux文件系统的说明，在手机root目录下能找到。

-s:表示对img文件进行压缩，去除img文件系统空白部分，得到数据文件占用空间的真实大小。

-t:表示unix时间戳，对img文件设置修改时间，可用在站长之家转换需要的时间戳。

<filename>:表示输出的文件名。

<directory>:表示输入的文件目录。

补充说明：

1）-l <limit size>中limit size大小单位为m，该值的大小受限于分区大小，如果制作出来的镜像大小大于该值，将会提示失败。对于分区的大小可以通过df命令获得。

2）用pull命令对手机中的file_contexts文件进行提取

先查看该系统中是否有file_contexts文件，再pull出该文件。

ok，现在我们就可以对文件进行打包了。

make_ext4fs -s file_contexts -s -l 3072m -a system system.img ./system

三.批处理脚本实现快速定制rom包

也许做过rom的都知道：

1.对于4.4系统的手机，如果要打入apk到system区，只需将apk复制到system/app下，对应apk的lib文件（.so文件）复制到system/lib下即可；如果要打入apk到userdata区，只需将apk复制到userdata/app下即可。

2.对于5.0及以上系统的手机，如果要打入apk到system区，需要将apk及对应的lib文件建在同一目录下，然后复制到system/app下（具体查看system/app下其他apk的目录格式），并且，在实践中，有的手机需要打入到system/framework中apk才能正常运行，不然闪退；如果需要打入apk到userdata区，同样只需将apk复制到userdata/app下即可。

几点说明：

1.由于需要解压出apk下的lib文件，而且，用winrar带的rar和unrar并不支持apk格式，所以用了好压的解压功能。将好压的安装目录配置到系统的path环境即可。这样就可以在命令行调用haozipc命令，在安装目录下也有命令行的说明文档，具体可自行安装查看。

2.由于有的手机需要打入system/framework中apk才能正常启动，因此在批处理时加入手动选择是否打入。

3.对于系统分区限制大小，可以先df出，存入txt列表中，让脚本自动读取。如：

4.实践中，5.0及以上系统，打入system区的apk可能不能包含中文名字。避免频繁更改，同样可以建一个txt文件，让脚本自动更改。如：

5.对于5.0及以上系统请先pull file_contexts文件到当前目录。

批处理脚本如下：makerom.zip（下载）

@echo off
title 定制rom包 by 小猴子jerry
echo -------------------------------------------------------------------------
echo 注意：请务必输入正确的安卓系统和底包编号，否则做包无效
echo 安卓系统（4.4/5.0）、底包编号（01等）
echo 安卓系统5.0及以上请输入5.0
echo -------------------------------------------------------------------------
pause
set /p version=请输入安卓系统版本号(4.4/5.0):
set /p var=请输入底包编号:
if exist .\sysapk set /p is_framework=是否需要打入apk到framework中(y/n):
echo ----------------请仔细核对，若输入有误请关闭程序重新输入-----------------
pause
if %version%==4.4 (
%打包system%
if exist .\system (
echo system.img正在制作中...
if exist .\sysapk (
echo 正在解压需要的.so文件...
for /f "delims=" %%a in ('dir /b/a-d/on .\sysapk\*.*') do (
haozipc x .\sysapk\%%a -o.\syslib lib\armeabi\*.* -y -sn)
copy sysapk\*.* system\app
move syslib\lib\armeabi\*.* system\lib
rd/s/q syslib)
for /f "skip=1 tokens=1,2,3" %%i in (limit.txt) do ( 
if %%i==%var% make_ext4fs -s -l %%j -a system ./system.img ./system
)
echo system.img制作完成)
%打包userdata%
if exist .\userdata (
echo userdata.img正在制作中...
if exist .\userapk (
if not exist userdata\app ( md userdata\app )
copy userapk\*.* userdata\app)
for /f "skip=1 tokens=1,2,3" %%i in (limit.txt) do ( 
if %%i==%var% make_ext4fs -s -l %%k -a data ./userdata.img ./userdata
)
echo userdata.img制作完成)
if not exist .\system (
if not exist .\userdata (
echo 找不到system or userdata文件夹，请拷贝system或userdata到当前目录))
%处理update文件%
if not exist .\update.rom (
echo 找不到update文件，请拷贝update.rom到当前目录)
if exist .\update.rom (
ren update.rom update.zip
haozipc d -tzip update.zip -ri!images\system images\userdata -sn
if not exist .\images ( md .\images )
if exist .\system.img ( move system.img .\images)
if exist .\userdata.img ( move userdata.img .\images)
haozipc a -tzip update.zip .\images\ -sn)
ren update.zip update.rom
rd/s/q system
rd/s/q userdata
rd/s/q images
echo 定制rom包制作完成！！)
rem =========================================================================================================================
if %version%==5.0 (
%前提：从手机中pull出需要的file_contexts文件%
%打包system%
if exist .\system (
echo system.img正在制作中...
if exist .\sysapk (
echo 正在解压需要的.so文件...
for /f "tokens=1,2 delims=." %%a in ('dir /b/a-d/on .\sysapk\*.*') do (
if %%a==usbhelp ( ren .\sysapk\usbhelp.apk com.service.usbhelper.apk
md .\syslib\com.service.usbhelper
move .\sysapk\com.service.usbhelper.apk .\syslib\com.service.usbhelper)
for /f "tokens=1,2 delims=:" %%i in (applist.txt) do ( 
if %%a==%%i ( ren .\sysapk\%%a.apk %%j.apk
haozipc x .\sysapk\%%j.apk -o.\syslib\%%j lib\armeabi\*.* -y -sn
ren .\syslib\%%j\lib\armeabi arm
move sysapk\%%j.apk syslib\%%j)))
if %is_framework%==y ( xcopy/s/y syslib system\framework) else (
xcopy/s/y syslib system\app)
rd/s/q syslib)
for /f "skip=1 tokens=1,2,3" %%i in (limit.txt) do ( 
if %%i==%var% make_ext4fs -s file_contexts -s -l %%j -a system ./system.img ./system)
echo system.img制作完成)
%打包userdata%
if exist .\userdata (
echo userdata.img正在制作中...
if exist .\userapk (
if not exist userdata\app ( md userdata\app )
move userapk\*.* userdata\app)
for /f "skip=1 tokens=1,2,3" %%i in (limit.txt) do ( 
if %%i==%var% make_ext4fs -s file_contexts -s -l %%k -a data ./userdata.img ./userdata)
echo userdata.img制作完成)
del file_contexts
if not exist .\system (
if not exist .\userdata (
echo 找不到system or userdata文件夹，请拷贝system或userdata到当前目录))
%处理update文件%
haozipc d -tzip update.zip -ri!images\system images\userdata -sn
if not exist .\images ( md .\images )
if exist .\system.img ( move system.img .\images)
if exist .\userdata.img ( move userdata.img .\images)
haozipc a -tzip update.zip .\images\ -sn
ren update.zip update.rom
rd/s/q system
rd/s/q userdata
rd/s/q images
rd/s/q sysapk
rd/s/q userapk
echo 定制rom包制作完成！！)
pause 

注意：

目录设置为如下：

运行bat：

通过本文的学习，又一次复习了常用的命令行命令，同时也希望本文所述对大家也有所帮助。