ASP知识讲座四
程序员文章站
2022-12-25 23:10:53
asp内置组件前三讲中，我们主要介绍了asp提供的四大内置对象：l response对象：向浏览器...
asp内置组件
前三讲中，我们主要介绍了asp提供的四大内置对象：
l response对象：向浏览器发送信息。
l request对象：访问从浏览器发送到服务器的信息（如获取表单数据）。
l session对象：存储、读取特定用户对话信息。
l application对象：存储、读取所有用户共享的应用程序信息。
此外还有server对象和objectcontext对象我们将在以后的实例中学习（提示：其实不经意之间你已经可以利用所学知识编写网上聊天室了）。本讲的内容是使用asp的activex server components（组件）。
一、 browser capabilities component（浏览器能力组件）：
我们知道，不同的浏览器也许支持不同的功能，如有些浏览器支持框架，有些不支持。利用这个组件，可以检查浏览器的能力，使你的网页争对不同的浏览器显示不同的页面（如对不支持frame的浏览器显示不含frame的网页）。该组件的使用很简单，需注意的是，要正确使用该组件，必须保证browscap.ini文件是最新的（其实每一个浏览器及其特性都列在这个文件中，自己打开看看就明白了）,否则结果可能相去甚远，如win98第二版所带的ie5.0，在下例中显示为netscape。这个文件一般位于web服务器的"\winnt\system32\inetsrv"下，最新的版本可去http://www.asptracker.com/或http://www.cyscape.com/browscap下载。
例：wuf22.asp
<html>
<body>
'注意：组件的使用与对象类似，但是组件在使用前必须先创建，而使用内置对象前不必创建。
<%set browscap=server.createobject("mswc.browsertype")%>
请稍候......
<p>
<table border=1 cellpadding=10>
<tr><td>浏览器类型</td><td><%=browscap.browser%></td></tr>
<tr><td>浏览器版本</td><td><%=browscap.version%></td></tr>
<tr><td>是否支持表格</td><td><%=browscap.tables%></td></tr>
<tr><td>是否支持activex控件</td><td><%=browscap.activexcontrols%></td></tr>
<tr><td>是否支持javaapplets</td><td><%=browscap.javaapplets%></td></tr>
<tr><td>是否支持javascript</td><td><%=browscap.javascript%></td></tr>
<tr><td>是否支持cookies</td><td><%=browscap.cookies%></td></tr>
<tr><td>是否支持frames</td><td><%=browscap.frames%></td></tr>
<tr><td>操作系统</td><td><%=browscap.platform%></td></tr>
<tr><td>是否支持vbscript</td><td><%=browscap.vbscript%></td></tr>
</table>
<%set browscap = nothing%>
</body>
</html>
注意：在本例中我们也接触了server对象的createobject方法，server.createobject用于创建已经注册到服务器上的activex组件（说明：还有其他方法可以创建组件）。不过别忘了用"set 对象 = nothing"来及时释放资源，这应该成为一个习惯。
二、 file access组件
file access组件由filesystemobject对象和textstream对象组成，使用filesystemobject对象，可以建立、检索、删除目录及文件，而textstream对象则提供读写文件的功能。
实例wuf23.asp。强调：只有通过实践才能加深理解，实践和比较程序运行结果是快速掌握编程技巧的最好方法。
<%@ language=vbscript %>
<% option explicit
' 注意绝对路径: c:\inetpub\home\asp\wuf23.asp 主页路径: c:\inetpub\home
dim path, file, fso, ctf, str, strhtml, strnohtml
'使用 createobject 方法创建 filesystemobject 对象 fso
set fso = server.createobject("scripting.filesystemobject")
path = server.mappath("test") '返回test的物理目录(绝对路径)
'就本例而言, 下面这句与上面这句返回的path完全一样
'path = server.mappath("\asp\test\")
response.write path & "<br>"
if fso.folderexists(path) = false then '判断该文件夹是否存在
fso.createfolder(path) '新建文件夹
end if
file = path & "\asptest.txt"
' 写文件操作
if fso.fileexists(file) = true then '判断该文件是否存在
'建立 textstream 对象 ctf
set ctf = fso.opentextfile(file, 8, false, 0) '打开文件, 详见说明
else
set ctf = fso.createtextfile(file,false, false) '新建文件
end if
ctf.write "<p>第一个字符串; " '写字符串
ctf.writeline "第二个字符串; " '写字符串, 并加上一个换行符
ctf.write "第三个字符串; "
ctf.close '注意要关闭文件
' 读文件操作
set ctf = fso.opentextfile(file, 1,,0)
do while ctf.atendofstream <> true '判别是否文件结尾（循环语句）
str = ctf.readline '（每次）读取一行
strnohtml = strnohtml & str & "<br>" & vbcrlf
strhtml = strhtml & server.htmlencode(str) & "<br>" & vbcrlf
loop
response.write strnohtml
response.write strhtml
ctf.close
set ctf = nothing '释放对象
set fso = nothing
%>
ctf = fso.opentextfile(file, 8, false, 0)，括号内第一个参数为文件名；第二个参数为8，表示在原文件后追加内容，若为1表示只读，为2则会重写原文件；第三个参数false表示，若指定文件不存在，也不新建文件，若为true，表示指定文件不存在，则新建该文件；第四个参数0表示以ascii文件格式打开，若为-2，则表示以原来的格式打开。
ctf = fso.createtextfile(file,false, false)，第二个参数false表示不覆盖已有文件，若为true，则表示覆盖（overwrite）已有文件；第三个参数为false表示文件格式为ascii，为true表示文件格式为unicode。
server对象的mappath方法将指定的虚拟路径转换为真实的文件路径。mappath将"/"和"\"字符视为相同。
server对象的htmlencode方法允许你对特定的字符串进行html编码，或者说使浏览器中可以正确显示特定的字符。上例中，若未编码，则"<p>"显示不出来，而是被浏览器作为html标记，你可以对比一下运行结果。
实际上，file access组件对文件、文件夹和驱动器的操作还是比较强大的，也提供了较多的方法，如果需要用到这方面的知识，别忘了使用它。
另外，到现在为止，写一个网页计数器已经是小菜一碟了吧，难怪那么多的网页提供免费计数器。怎么样？自己写一个图形计数器试试看，想怎么作弊就怎么作弊，完全自己说了算，爽呆！（小秘密：我的主页上有实例wuf24.asp）
三、 ad rotator（广告翻转组件）
现在上网，恐怕最讨厌的是别人主页上的广告条，最喜欢的是自己主页上的广告条，广告条如同垃圾邮件一样，比比皆是，防不胜防。你也可以自己动手制造这样的垃圾，asp的ad rotator组件就可使每次打开或者重新加载网页时，随机的显示广告。这个例子包括三部分：
例程wuf25.asp
<%@ language=vbscript %>
<% option explicit
dim adr
'创建 ad rotator 对象
set adr = server.createobject("mswc.adrotator")
adr.border = 2 '指定图形文件的边框大小
adr.clickable = true '指示显示的图片是否是一个超链接
adr.targetframe = "_blank" '设置超链接是否要指定frame名称,如: _top _new _parent
'获取将要显示的图片及超链接设置 - 在文件 adrset.txt 中设置
response.write adr.getadvertisement("adrset.txt")
%>
adrset.txt内容（后面为注释，不是这个文件的内容）：
redirect wuf26.asp 点击广告后，转由wuf26.asp来处理
width 468 广告图片宽度
height 60 广告图片高度
* 分隔符
http://www.soyou.com/prog/ad/468x60_1.gif 广告图片所在位置，也可为本地图形文件
http://www.163.com/ 指向链接，若没有超链接，写入一个"-"
网易 文字说明
20 显示该广告的相对权重，即显示频率
http://fp.cache.imgis.com/images/ad173962st1sz1sq1id2.gif
http://www.sina.com.cn/
新浪网
30
http://61.139.77.73/images/canon.gif 也可以使用本地图片，如../images/flag.gif
http://www.canon.com.cn/
佳能
50
本例中一共有三个图片（图片大小468x60）及链接，每个链接的描述占四行，实际使用时，你可如法炮制，增加更多的图片。
<% 'wuf26.asp
url = request.querystring("url")
response.redirect(url)
%>
wuf26.asp是一个最简单的处理程序，你可根据实际需要在这里加入更多的代码。
运行一下，原来这个组件的使用也很简单，你要做的就是得到自己的adrset.txt文件。利用这个组件，你甚至可以设计一个现在已非常时髦的广告交换主页。
四、 content linking组件
显然这个组件与链接有关系，如果想马上知道这个组件的具体用途，恐怕还操之过急，不妨先引用一个经典的例子：假设在网上阅读一本书，你对以下这些链接一定不会陌生：第1章、第2章、…、上一章、下一章（或前一页、后一页）等等。我们现在要做的就是如何在这些链接之间方便快速地设置跳转。
首先建一个链接列表文本文件，如urllist.txt
wuf23.asp 第1章：文件操作（file access组件）
wuf28.asp 第2章：content linking组件使用示例
wuf22.asp 第3章：浏览器能力组件
链接url地址和描述之间用 tab 键分隔。下面wuf27.asp用来列出urllist.txt中的所有链接。
<% @language = vbscript %>
<% option explicit %>
<html><head><title>content linking组件使用</title></head>
<body>
<h2>目录列表: 注意核心链接是第2章, 你一定要点击它</h2>
<ul>
<%
dim nextlink, count
'建立 content linking 组件
set nextlink = server.createobject("mswc.nextlink")
'获取文件 urllist.txt 中链接数目
count = nextlink.getlistcount("urllist.txt")
dim url, dscr, i
for i = 1 to count
url = nextlink.getnthurl ("urllist.txt", i) '取得超链接
dscr = nextlink.getnthdescription ("urllist.txt", i) '取得文字描述
response.write "<li><a href = """ & url & """>" & dscr & "</a>" & vbcrlf
next
%>
</ul></body></html>
然后，以wuf28.asp为例说明如何自动实现上一章和下一章跳转。
<% @language = vbscript %>
<% option explicit %>
<html><head><title>这个链接要注意</title></head>
<body>
<p>这里是第 2 章的正文............</p>
<% '每个文件都包含下面这句, 就实现了自动链接%>
<!--#include file="wuf29.asp"-->
</body></html>
这里最后一句加上去就可以实现自动跳转，核心在wuf29.asp中。
<%
dim nextlink, rank
set nextlink = server.createobject ("mswc.nextlink")
'当前的链接在 urllist.txt 中位于第几个
rank = nextlink.getlistindex ("urllist.txt")
response.write "<hr>"
if (rank > 1) then 'rank = 1 不存在前一页
response.write "|<a href=""" & nextlink.getpreviousurl("urllist.txt") & """>上一章</a>|"
end if
if (rank < nextlink.getlistcount("urllist.txt")) then 'rank在最后, 则没有下一页
response.write "|<a href=""" & nextlink.getnexturl("urllist.txt") & """>下一章</a>|"
end if
%>
运行这个例子后，你马上能真正理解这个组件的作用，简而言之，就是不需要在每页都写一个"上一章"、"下一章"，完全通过wuf29.asp一下搞定，是不是很方便？！不然你要是手工修改链接的话，不是太麻烦了几点吗？
现在你应该明白了，网上大量的免费计数器、免费留言板、免费聊天室、广告交换网等等……，其原理都不过如此，大可不必崇拜。
上一篇： 提升PHP执行速度全攻略
下一篇： 把PHP安装为Apache DSO