欢迎您访问程序员文章站本站旨在为大家提供分享程序员计算机编程知识！
您现在的位置是： 首页  >  IT编程

WIFI模块的常用功能开发和遇到的问题，以及解决方法

程序员文章站 2022-06-26 09:12:22
目录一、建立网络（AP）二、连接ESP所建立的网络三、接入网络（STA）进阶练习常用方法说明四、扫描网络同步搜索异步搜索五、简单应用六、总结上期我们介绍了esp32wifi功能的初始化以及状态机的相关知识。这期我们从建立网络、连接网络、搜索网络以及WiFi功能的简单应用这个方面，来系统化的了解esp32中的WiFi功能。一、建立网络（AP）建立网络只需两步：引用WiFi库#include ；启动AP网络WiFi.so.....

目录

一、建立网络（AP）

二、连接ESP所建立的网络

三、接入网络（STA）

进阶练习

常用方法说明

四、扫描网络

同步搜索

异步搜索

五、简单应用

六、总结

上期我们介绍了esp32wifi功能的初始化以及状态机的相关知识。这期我们从建立网络、连接网络、搜索网络以及WiFi功能的简单应用这个方面，来系统化的了解esp32中的WiFi功能。

一、建立网络（AP）

建立网络只需两步：

  1. 引用WiFi库#include <WiFi.h>；
  2. 启动AP网络WiFi.softAP(ssid)；

将下面代码上传到模块中： 

#include <WiFi.h>

void setup()
{
  WiFi.softAP("ESP32_AP_gzfdwl");
}

void loop()
{
}

这个代码比较好理解，首先第1行表示WiFi这个功能的库，而在主函数中的esp32AP_gzfdwl可以作为我们网络的名称，这个名称可以随意修改，但是字符不易过长，这个字符是有一定限度的，如果太长的话，可能会引起程序的编译错误。

由于这个网络的名字太长了，我改成了最基础的名字ESP32_AP_TEST，连接状态如下图

WIFI模块的常用功能开发和遇到的问题，以及解决方法

二、连接ESP所建立的网络 

#include <WiFi.h>

IPAddress local_IP(192,168,4,22);
IPAddress gateway(192,168,4,22);
IPAddress subnet(255,255,255,0);

const char *ssid = "ESP32_AP_TEST";
const char *password = "12345678";

void setup()
{
  Serial.begin(115200);
  Serial.println();
  
  WiFi.mode(WIFI_AP); //设置工作在AP模式

  WiFi.softAPConfig(local_IP, gateway, subnet); //设置AP地址
  while(!WiFi.softAP(ssid, password)){}; //启动AP
  Serial.println("AP启动成功");

  Serial.print("IP address: ");
  Serial.println(WiFi.softAPIP()); // 打印IP地址

  WiFi.softAPsetHostname("myHostName"); //设置主机名
  Serial.print("HostName: ");
  Serial.println(WiFi.softAPgetHostname()); //打印主机名

  Serial.print("mac Address: ");
  Serial.println(WiFi.softAPmacAddress()); //打印mac地址
}

void loop()
{
  delay(1000);
  Serial.println(WiFi.softAPgetStationNum()); //打印客户端连接数
}

其中第5行和第6行分别是我们建立网络的名称和接入网络的密码。在主函数中，我们第1步首先设置串口的波特率为115200，其次，让串口打印相关的信息。接着我们设置WiFi的工作模式为AP模式，设置AP的地址，启动AP，当AP正确启动后，在窗口中打印出AP启动成功的字样，并打印AP地址，其中主机的名称我们可以随意填写，并将由串口打印出来，最后的lop语句中，我们让其一直执行不断的打印出客户端连接的数目。具体的功能实现如下图所示。
WIFI模块的常用功能开发和遇到的问题，以及解决方法

三、接入网络（STA）

上面的过程是我们esp32作为热点直接建立网络，接下来我们让esp32接入其他的网络。
连接到网络也只需要两步：

  1. 引用WiFi库#include <WiFi.h>；
  2. 连接到网络WiFi.begin(ssid, password);；

将下面代码上传到模块中： 

#include <WiFi.h>

const char *ssid = "********"; //你的网络名称
const char *password = "********"; //你的网络密码

void setup()
{
  Serial.begin(115200);
  Serial.println();

  WiFi.begin(ssid, password); //连接网络

  while (WiFi.status() != WL_CONNECTED) //等待网络连接成功
  {
    delay(500);
    Serial.print(".");
  }
  Serial.println("WiFi connected!");

  Serial.println("IP address: ");
  Serial.println(WiFi.localIP()); //打印模块IP
}

void loop()
{
}

其实这个过程也很简单，第1步先声明WiFi库。然后输入我们要接入的网络名称和网络的密码。在主函数中设置波托率为115200以及打印相关的信息。使用while语句来不断的尝试连接网络，指导网络连接成功，然后，由串口打印出WiFi已经连接以及IP地址的字样。
WIFI模块的常用功能开发和遇到的问题，以及解决方法

进阶练习 

#include <WiFi.h>

const char *ssid = "********";
const char *password = "********";

void setup()
{
  Serial.begin(115200);
  Serial.println();

  WiFi.mode(WIFI_STA); //设置工作在STA模式

  WiFi.begin(ssid, password); //连接网络

  while (!WiFi.isConnected()) //等待网络连接成功
  {
    delay(500);
    Serial.print(".");
  }
  Serial.println("WiFi connected!");

  Serial.print("IP address: ");
  Serial.println(WiFi.localIP()); //打印模块IP

  Serial.print("subnetMask: ");
  Serial.println(WiFi.subnetMask()); //打印子网掩码

  Serial.print("gateway: ");
  Serial.println(WiFi.gatewayIP()); //打印网关地址

  Serial.print("dns: ");
  Serial.println(WiFi.dnsIP()); //打印DNS地址

  Serial.print("mac Address: ");
  Serial.println(WiFi.macAddress()); //打印mac地址

  WiFi.setHostname("myHostName"); //设置主机名
  Serial.print("HostName: ");
  Serial.println(WiFi.getHostname()); //打印主机名

  Serial.println(WiFi.status());
  WiFi.disconnect(); //断开当前网络
  delay(1000);
  Serial.println(WiFi.status());
}

void loop()
{
}

以上是进入网络较为简单的应用，我们看一点相对复杂的变化。代码如下，前几步和上面的代码内容大致相同，我们通过函数的调用方法来打印出IP模块的IP，打印出子网掩码网关地址，nds地址等等一些东西。这一块的内容我掌握的不是很好，嗯，如果大家有疑问的话，可以看下面的内容。

常用方法说明

  • wl_status_t begin(const char* ssid, const char *passphrase = NULL, int32_t channel = 0, const uint8_t* bssid = NULL, bool connect = true)
    wl_status_t begin(char* ssid, char *passphrase = NULL, int32_t channel = 0, const uint8_t* bssid = NULL, bool connect = true)
    该方法用来接入网络；
  • bool config(IPAddress local_ip, IPAddress gateway, IPAddress subnet, IPAddress dns1 = (uint32_t)0x00000000, IPAddress dns2 = (uint32_t)0x00000000)
    设置网络地址；
  • bool disconnect(bool wifioff = false, bool eraseap = false)
    断开网络连接，若wifioff为true则还将还原网络设置，若eraseap为true则将清除保存于flash中的网络参数；
  • bool isConnected()
    返回是否已接入网络；
  • bool setAutoReconnect(bool autoReconnect)
    设置断网自动重连接；
  • bool getAutoReconnect()
    返回是否自动重连接；
  • IPAddress localIP()
    返回模块地址；
  • IPAddress subnetMask()
    返回子网掩码；
  • IPAddress gatewayIP()
    返回网关地址；
  • IPAddress dnsIP(uint8_t dns_no = 0)
    返回DNS地址；
  • uint8_t * macAddress(uint8_t* mac)
    String macAddress()
    返回MAC地址；
  • const char * getHostname()
    返回主机名字；
  • bool setHostname(const char * hostname)
    设置主机名字；
  • wl_status_t status()
    返回联网状态，状态如下：
    255：WL_NO_SHIELD不用在意（兼容WiFi Shield而设计）
    0：WL_IDLE_STATUS正在WiFi工作模式间切换；
    1：WL_NO_SSID_AVAIL无法访问设置的SSID网络；
    2：WL_SCAN_COMPLETED扫描完成；
    3：WL_CONNECTED连接成功；
    4：WL_CONNECT_FAILED连接失败；
    5：WL_CONNECTION_LOST丢失连接；
    6：WL_DISCONNECTED断开连接；

WIFI模块的常用功能开发和遇到的问题，以及解决方法

四、扫描网络

了解完接入网络，然后我们了解一下esp32模块搜索网络的功能。

同步搜索

使用下面代码搜索并打印搜索到的网络信息： 

#include <WiFi.h>

void setup()
{
  Serial.begin(115200);
  Serial.println();

  WiFi.mode(WIFI_STA); //设置为STA模式
  WiFi.disconnect();   //断开当前可能的连接
  delay(100);

  Serial.println("scan start");
  int n = WiFi.scanNetworks(); //扫描并返回搜索到的网络数量，该方法默认会阻塞
  Serial.println("scan done");
  if (n != 0)
  {
    Serial.print(n);
    Serial.println(" networks found");
    for (int i = 0; i < n; ++i)
    {
      Serial.println();
      Serial.print(i + 1);
      Serial.print(":       ");
      Serial.print(WiFi.SSID(i)); //打印网络名称
      Serial.print("        ");
      Serial.print(WiFi.RSSI(i)); //打印信号强度
      Serial.print("        ");
      Serial.print((WiFi.encryptionType(i) == WIFI_AUTH_OPEN) ? "未加密" : "加密"); //打印是否加密
      delay(10);
    }
  }
}

void loop()
{
}

首先我们打开串口设置不妥率为115200，并设置WiFi的工作模式为sta模式。要想搜索网络第1步首先要断开自身的网络链接。第2步我们使用如下的函数来实现网络的搜索，通过字符打印函数输出网络的名称，并打印出信号的强度，用判断语句来输出这个网络是否加密。
WIFI模块的常用功能开发和遇到的问题，以及解决方法

异步搜索

使用下面代码进行异步搜索，异步搜索不会阻塞程序运行：异步搜索相对于同步搜索就是不会堵塞程序的运行，也就是速度更快。但是他的搜索范围，相对于同步搜索较小。 

#include <WiFi.h>

void setup()
{
  Serial.begin(115200);
  Serial.println();

  WiFi.mode(WIFI_STA); //设置为STA模式
  WiFi.disconnect();   //断开当前可能的连接
  delay(100);

  Serial.println("开始扫描");
  WiFi.scanNetworks(true); //启动异步扫描
}

void loop()
{
  delay(1000);
  int n = WiFi.scanComplete(); //获取扫描状态
  if (n >= 0)
  {
    Serial.println("扫描完成");
    for (int i = 0; i < n; ++i)
    {
      Serial.println();
      Serial.print(i + 1);
      Serial.print(":       ");
      Serial.print(WiFi.SSID(i)); //打印网络名称
      Serial.print("        ");
      Serial.print(WiFi.RSSI(i)); //打印信号强度
      Serial.print("        ");
      Serial.print((WiFi.encryptionType(i) == WIFI_AUTH_OPEN) ? "未加密" : "加密"); //打印是否加密
      delay(10);
    }
    WiFi.scanDelete(); //清除内存中的扫描结果
  }
  else if (n == -1)
  {
    Serial.println("正在扫描");
  }
  else if (n == -2)
  {
    Serial.println("未进行扫描");
  }
}

WIFI模块的常用功能开发和遇到的问题，以及解决方法

五、简单应用 

#include <WiFi.h>

const char *ssid = "********";
const char *password = "********";

void myEvent1(WiFiEvent_t event) //事件回调函数
{
  switch (event)
  {
  case SYSTEM_EVENT_STA_CONNECTED:
    Serial.println("已连接到网络");
    break;
  default:
    break;
  }
}

void myEvent2(WiFiEvent_t event, WiFiEventInfo_t info) //事件回调函数
{
  Serial.println("获取到IP");
}

void setup()
{
  Serial.begin(115200);
  Serial.println();

  WiFi.disconnect(true); //关闭网络

  WiFi.onEvent(myEvent1); //注册事件方法一

  WiFi.onEvent(myEvent2, WiFiEvent_t::SYSTEM_EVENT_STA_GOT_IP); //注册事件方法二

  WiFiEventId_t myEvent3ID = WiFi.onEvent( //注册事件方法三
      [](WiFiEvent_t event, WiFiEventInfo_t info) {
        Serial.print("网络连接已断开");
      },
      WiFiEvent_t::SYSTEM_EVENT_STA_DISCONNECTED);

  WiFi.mode(WIFI_STA);        //设置工作在STA模式
  WiFi.begin(ssid, password); //连接网络

  while (!WiFi.isConnected()) //等待网络连接成功
  {
    delay(500);
  }

  delay(1000);
  WiFi.disconnect(); //断开当前网络

  //WiFi.removeEvent(myEvent3ID); //删除事件
}

void loop()
{
}

首先我们先输入要接入的网络名称和密码，然后我们设置事件回调函数。我们第1个事件设置为网络连接事件，第2个事件设置为IP获取事件，第3个事件则是，断开网络事件。最后，我们删除所有事件。然后最后的串口，监视器中就会显示如下的情况。WIFI模块的常用功能开发和遇到的问题，以及解决方法

六、总结

Esp32 WiFi.模块的基本使用功能。本次主要讲解了WiFi的网络建立，网络链接，网络搜索以及简单的网络时间调用等方面的知识。总体来说是比较容易理解的。但是有一点也需要注意，我们在设置网络名称的时候要尽量简短。当然在实践中也需要注意，下载好程序之后，需要等段一段时间再查看串口助手。否则看到的都是乱码。

本文地址：https://blog.csdn.net/weixin_42619971/article/details/107895046

相关标签： 通信 wifi模块

上一篇： VM虚拟机克隆_修改网络

下一篇： vue-quill-editor之图片上传、大小缩放及内容粘贴、长度限制

推荐阅读