shader篇-处理复杂光照

标签（空格分隔）： shader

---

• shader篇-处理复杂光照

unity光源类型介绍

1.平行光：几何属性只有方向，光照不会衰减
2.点光源：光源中心光照最强，球边界光照最弱，为0
3.聚光灯：由一个特定位置出发，有着锥形光照区域的光源。顶点光照最强，锥形变边界光照最弱，为0

前向渲染中处理不同光源

前向渲染说明
先说明一下前向渲染，unity支持多种渲染路径，前向渲染是其中一种

Tags { "LightMode"="ForwardBase" }

一般使用以上规定前向渲染。
对前向渲染而言，一个shader通常会规定2个pass，一个是Bass Pass,仅执行一次，一个是Additional Pass，为每个光源会执行一次。

代码实例
首先是第一个pass,也就是 Base Pass

Pass {

Tags { "LightMode"="ForwardBase" }
CGPROGRAM
#pragma multi_compile_fwdbase   

上面代码设置了渲染路径的同时使用#pragma multi_compile_fwdbase指令保证Shader使用光照衰减等光照变量时可以正确被赋值。

完整的Base Pass

Pass {

    Tags { "LightMode"="ForwardBase" }

    CGPROGRAM


    #pragma multi_compile_fwdbase   

    #pragma vertex vert
    #pragma fragment frag

    #include "Lighting.cginc"

    fixed4 _Diffuse;
    fixed4 _Specular;
    float _Gloss;

    struct a2v {
        float4 vertex : POSITION;
        float3 normal : NORMAL;
    };

    struct v2f {
        float4 pos : SV_POSITION;
        float3 worldNormal : TEXCOORD0;
        float3 worldPos : TEXCOORD1;
    };

    v2f vert(a2v v) {
        v2f o;
        o.pos = UnityObjectToClipPos(v.vertex);

        o.worldNormal = UnityObjectToWorldNormal(v.normal);

        o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;

        return o;
    }

    fixed4 frag(v2f i) : SV_Target {
        fixed3 worldNormal = normalize(i.worldNormal);
        fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);

        fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;

        fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * max(0, dot(worldNormal, worldLightDir));

        fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz);
        fixed3 halfDir = normalize(worldLightDir + viewDir);
        fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(worldNormal, halfDir)), _Gloss);

        fixed atten = 1.0;

        return fixed4(ambient + (diffuse + specular) * atten, 1.0);
    }

    ENDCG
}

在Base Pass里只处理环境光和平行光，如果有多个平行光，会选择最亮的平行光

Additional Pass

Pass {

    Tags { "LightMode"="ForwardAdd" }

    Blend One One

    CGPROGRAM


    #pragma multi_compile_fwdadd

相比之前的Base pass，Additional Pass多了Blend命令开启了混合模式，这样的光照可以与之前的叠加，而不是覆盖之前的光照效果。

完整的Additional Pass

Pass {

    Tags { "LightMode"="ForwardAdd" }

    Blend One One

    CGPROGRAM


    #pragma multi_compile_fwdadd

    #pragma vertex vert
    #pragma fragment frag

    #include "Lighting.cginc"
    #include "AutoLight.cginc"

    fixed4 _Diffuse;
    fixed4 _Specular;
    float _Gloss;

    struct a2v {
        float4 vertex : POSITION;
        float3 normal : NORMAL;
    };

    struct v2f {
        float4 pos : SV_POSITION;
        float3 worldNormal : TEXCOORD0;
        float3 worldPos : TEXCOORD1;
    };

    v2f vert(a2v v) {
        v2f o;
        o.pos = UnityObjectToClipPos(v.vertex);

        o.worldNormal = UnityObjectToWorldNormal(v.normal);

        o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;

        return o;
    }

    fixed4 frag(v2f i) : SV_Target {
        fixed3 worldNormal = normalize(i.worldNormal);
        #ifdef USING_DIRECTIONAL_LIGHT
            fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
        #else
            fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz - i.worldPos.xyz);
        #endif

        fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * max(0, dot(worldNormal, worldLightDir));

        fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz);
        fixed3 halfDir = normalize(worldLightDir + viewDir);
        fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(worldNormal, halfDir)), _Gloss);

        #ifdef USING_DIRECTIONAL_LIGHT
            fixed atten = 1.0;
        #else
            #if defined (POINT)
                float3 lightCoord = mul(unity_WorldToLight, float4(i.worldPos, 1)).xyz;
                fixed atten = tex2D(_LightTexture0, dot(lightCoord, lightCoord).rr).UNITY_ATTEN_CHANNEL;
            #elif defined (SPOT)
                float4 lightCoord = mul(unity_WorldToLight, float4(i.worldPos, 1));
                fixed atten = (lightCoord.z > 0) * tex2D(_LightTexture0, lightCoord.xy / lightCoord.w + 0.5).w * tex2D(_LightTextureB0, dot(lightCoord, lightCoord).rr).UNITY_ATTEN_CHANNEL;
            #else
                fixed atten = 1.0;
            #endif
        #endif

        return fixed4((diffuse + specular) * atten, 1.0);
    }

    ENDCG
}

这里使用#ifdef判断处理的光照类型

如果是平行光，就可以直接通过_WorldSpaceLightPos0.xyz得到，如果不是_WorldSpaceLightPos0.xyz得到只是点光源的位置，我们需要这个位置减去世界空间的顶点位置才可以得到光源方向。
atten是不同光源下光照衰减的计算