一个用来学习CoAP协议的小例子

1 CoAP简介

CoAP 是受限制应用协议的简称，是物联网应用层协议之一。物联网应用层协议主要还有HTTP和MQTT，这三种协议有各自不同的应用场景。其中HTTP和MQTT使用TCP作为传输层协议，而CoAP使用UDP作为传输层协议，如下图：

虽然CoAP没有使用TCP作为传输层协议，但它也是TCP/IP协议族的一部分。CoAP借鉴了大量HTTP的经验，比如CoAP也使用请求/响应工作模式（客户端发送CoAP请求，服务器侦听到该请求后根据请求内容返回响应码和相应内容）。不过与HTTP不一样的是，CoAP专门为低功耗受限制设备设计，它比HTTP简单很多。

2 CoAP快速入门

2.1 框架

通过一个简单 例子 来进行CoAP的学习，平台结构如下

安装有libcoap的Linux主机作为CoAP客户端，而 WeMos D1 作为CoAP服务器。CoAP服务器提供数量有限的几种服务，在 RESTful 风格下，这些服务被称为资源，由WeMos D1组成的CoAP服务器具有一个hello资源，通过GET方法可获得hello资源，其包含一个固定字符串内容“Hello CoAP!”，此外还提供一个light资源，该资源支持GET方法和PUT方法访问，通过GET方法可获得该资源内容，通过PUT方法可以修改该资源的内容，结合GET和PUT方法，可以把虚拟资源的操作直接映射到真实资源中【此例中light资源对应于一个真实的LED灯，其与WeMos D1的引脚2相连】。

2.2 CoAP服务器实现

从代码仓库的first_demo/microcoap目录中获取实例代码，其中

• microcoap.ino为Arduino IDE的工程文件。
• coap.c和coap.h为CoAP的实现代码，该部分代码实现了CoAP首部解析和填充、选项解析和填充、负载分离和填充等功能。虽然 coap.c 和 coap.h 仅实现了CoAP的一部分基础功能，但对于本例子，这两个文件并不需要修改。

2.2.1 初始化

Arduino IDE的工程文件中，总有setup()和loop()函数，这点不知道的小伙伴可以学习下Arduino IDE编程，本例中setup()用于实现LED初始化，串口初始化，网络设备初始化等，部分代码如下所示：

//宏定义WeMos D1要连接的WiFi信息
#define AP_SSID "LaoLin"
#define AP_PSW "66684403"

//定义UDP变量及包缓存区域
EthernetUDP udp;
uint8_t packetbuf[256];

//传感器引脚以及对应变量
static int led = 2;
static char light = '0';

void setup()
{
    int i;
    pinMode(led, OUTPUT);
    Serial.begin(9600);
    Serial.println("Program is beginning");
    
    //连接WiFi
    WiFi.begin(AP_SSID, AP_PSW);
    Serial.print(String("Connecting to ")+AP_SSID);
    while (WiFi.status() != WL_CONNECTED){
        delay(500);
        //Serial.print(".");
    }
    Serial.print("\nConnected, IP address: ");
    
    //输出当前IP地址
    Serial.println(WiFi.localIP());

    //侦听5683端口的UDP输入数据
    udp.begin(5683);
    build_rsp();
}

2.2.2 CoAP数据处理

CoAP数据处理位于loop()函数内，处理流程如图所示：

具体代码如下所示：

void udp_send(const uint8_t *buf, int buflen)
{
    udp.beginPacket(udp.remoteIP(), udp.remotePort());
    while(buflen--)
        udp.write(*buf++);
    udp.endPacket();
}
void loop()
{
    int sz;
    int rc;
    coap_packet_t pkt;
    int i;
    if ((sz = udp.parsePacket()) > 0)
    {
        //读取UDP请求内容
        udp.read(packetbuf, sizeof(packetbuf));

        for (i = 0; i < sz; i++)
        {
            Serial.print(packetbuf[i], HEX);
            Serial.print(" ");
        }
        Serial.println("");

        //验证解析CoAP请求
        if (0 != (rc = coap_parse(&pkt, packetbuf, sz)))
        {
        	//CoAP数据包有问题
            Serial.print("Bad packet rc=");
            Serial.println(rc, DEC);
        }
        else
        {
            size_t rsplen = sizeof(packetbuf);
            coap_packet_t rsppkt;
            //处理CoAP请求
            coap_handle_req(&scratch_buf, &pkt, &rsppkt, endpoints);
            memset(packetbuf, 0, UDP_TX_PACKET_MAX_SIZE);
            //构造CoAP响应
            if (0 != (rc = coap_build(packetbuf, &rsplen, &rsppkt)))
            {
            	//CoAP响应构造失败
                Serial.print("coap_build failed rc=");
                Serial.println(rc, DEC);
            }
            else
            {
                //返回UDP数据包
                udp_send(packetbuf, rsplen);
            }
        }
    }
}

2.2.3 资源列表

endpoints列表是一组资源集合，当WeMos D1服务器收到CoAP请求时将遍历此资源集合，其中每个资源都由请求方法，请求处理函数，请求URI和媒体类型组成，具体代码如下：

coap_endpoint_t endpoints[] =
{
    {COAP_METHOD_GET, handle_get_well_known_core, &path_well_known_core, "ct=40"},
    {COAP_METHOD_GET, handle_get_hello, &path_hello, "ct=0"},
    {COAP_METHOD_GET, handle_get_light, &path_light, "ct=0"},
    {COAP_METHOD_PUT, handle_put_light, &path_light, NULL},
    {(coap_method_t)0, NULL, NULL, NULL}
};

2.2.3.1 hello 资源

资源定义需要两部分组成，分别是URI和请求处理函数，其代码如下：

//URI，可通过coap://IP/hello对该资源进行访问
static const coap_endpoint_path_t path_hello = {1, {"hello"}};
//请求处理函数
static int handle_get_hello(coap_rw_buffer_t *scratch, const coap_packet_t *inpkt, coap_packet_t *outpkt, uint8_t id_hi, uint8_t id_lo)
{
    char hello[32] = "Hello CoAP!";
    return coap_make_response(scratch, outpkt, (const uint8_t *)&hello, strlen(hello), id_hi, id_lo, &inpkt->tok, COAP_RSPCODE_CONTENT, COAP_CONTENTTYPE_TEXT_PLAIN);
}

2.2.3.2 light 资源

light资源与hello资源类似，其PUT方法的处理函数代码如下：

static int handle_put_light(coap_rw_buffer_t *scratch, const coap_packet_t *inpkt, coap_packet_t *outpkt, uint8_t id_hi, uint8_t id_lo)
{
    if (inpkt->payload.p[0] == '1')
    {
    	//CoAP请求的payload字段为1，则点亮LED灯
        light = '1';
        digitalWrite(led, HIGH);
        Serial.println("ON");
    }
    else
    {
    	//CoAP请求的payload字段为0，则熄灭LED灯
        light = '0';
        digitalWrite(led, LOW);
        Serial.println("OFF");
    }
    return coap_make_response(scratch, outpkt, (const uint8_t *)&light, 1, id_hi, id_lo, &inpkt->tok, COAP_RSPCODE_CHANGED, COAP_CONTENTTYPE_TEXT_PLAIN);
}

2.3 测试

使用已安装有libcoap的Linux主机对WeMos D1服务器发起访问，使用以下命令分别对资源进行访问：

./coap-client -m get coap://[ip]/hello
./coap-client -m get coap://[ip]/light
./coap-client -m put -e "1" coap://[ip]/light

3 CoAP核心

CoAP协议的核心部分内容包括如下内容：

• CoAP首部分析：版本编号、报文类型、标签长度指示、准则、报文序号、标签、选项、分隔符和负载。
• CoAP工作模式说明：CON、NON、ACK和RST。
• CoAP重传机制分析：CoAP请求丢失处理、CoAP响应丢失处理、最大重传次数、最大传输耗时、最大等待时间。
• CoAP方法说明：GET方法、POST方法、PUT方法和DELETE方法。
• CoAP响应码说明：正确响应、客户端错误、服务器错误。
• CoAP选项详细分析：选项格式、URI选项、Content-Format选项、Accept选项、Etag选项、If-Match选项、If-None-Match选项。
• CoAP媒体类型说明：link-format类型、文本类型、二进制类型、JSON类型。

由于网上本部分资料比较多，博主就不再重复，如有需要了解，找不到好的资料的，也可以下载博客最后面分享的书籍资料进行学习。

4 遇到的问题

• 刚开始学习CoAP，上网找到的资料基本上说的都是概念性的东西，项目类博客也说的云里雾里，不知道怎么动手操作一个实质性的项目，后来找到了这本书《IoT开发实战：CoAP卷》，PDF的下载链接放在超链接中，有需要的朋友可以自行下载，若是链接失效，可以留言提醒。不得不说要系统性的学习一门知识，还是书籍更好点。
• 各位看官有问题请留言。