无组件生成缩略图

网上有不少生成缩略图的asp组件。若你的虚拟空间不支持注册新组件，可能会感觉自己的网站失色不少。心晴不才，结合网上资源写了个无组件生成缩略图程序，仅供参考。

还是先看看基础部分吧。首先，我们知道在页面中显示图片是如下代码：


<img src="pic.gif" border="0" width="300" height="260">

src是图片路径，border控制图片边缘宽度，width是图片的长度，height是图片的高度。缩略图的生成其实就是在原始尺寸上缩放。但一般为了尽量少失真，我们都会按比例缩放。于是，获取图片的长宽尺寸也就成了生成缩略图的重点。

下面便是编写无组件生成缩略图的步骤：

1.无组件获取图片大小

以前刚学asp不久时看到过一篇利用ascii码实现无组件获取图片尺寸的文章。后来试了试，发现在获取jpg类图片尺寸时总是不能正确显示，在网上查了查，居然有不少网站转载这个程序，但没有一家指出此程序的缺陷，也就更谈不上解决缺陷的办法了。后来又google了一下，终于找到了一篇介绍利用adodb.stream获取图片尺寸的文章，按其介绍的方法，修改里面的代码试了试，效果真的还不错，现在将其拿出来与大家分享：

利用adodb.stream获取图片尺寸的通用类 <%
'//////////// gps：get picture size //////////////
'//////////////利用adodb.stream获取图片尺寸//////////////
'/////////cited by leon（心晴） 2005年8月11日//////////
class gps
dim aso
private sub class_initialize
set aso=createobject("adodb.stream")
aso.mode=3 
aso.type=1 
aso.open 
end sub

private sub class_terminate
set aso=nothing
end sub

private function bin2str(bin)
dim i, str
for i=1 to lenb(bin)
clow=midb(bin,i,1)
if ascb(clow)<128 then
str = str & chr(ascb(clow))
else
i=i+1
if i <= lenb(bin) then str = str & chr(ascw(midb(bin,i,1)&clow))
end if
next 
bin2str = str
end function

private function num2str(num,base,lens)
'gps (2005-8-11)
dim ret
ret = ""
while(num>=base)
ret = (num mod base) & ret
num = (num - num mod base)/base
wend
num2str = right(string(lens,"0") & num & ret,lens)
end function

private function str2num(str,base)
'gps (2005-8-11)
dim ret
ret = 0
for i=1 to len(str)
ret = ret *base + cint(mid(str,i,1))
next
str2num=ret
end function

private function binval(bin)
'gps (2002-8-11)
dim ret
ret = 0
for i = lenb(bin) to 1 step -1
ret = ret *256 + ascb(midb(bin,i,1))
next
binval=ret
end function

private function binval2(bin)
'gps (2002-8-11)
dim ret
ret = 0
for i = 1 to lenb(bin)
ret = ret *256 + ascb(midb(bin,i,1))
next
binval2=ret
end function

'///以下是调用代码///
function getimagesize(filespec) 
'gps (2002-8-11)
dim ret(3)
aso.loadfromfile(filespec)
bflag=aso.read(3)
select case hex(binval(bflag))
case "4e5089":
aso.read(15)
ret(0)="png"
ret(1)=binval2(aso.read(2))
aso.read(2)
ret(2)=binval2(aso.read(2))
case "464947":
aso.read(3)
ret(0)="gif"
ret(1)=binval(aso.read(2))
ret(2)=binval(aso.read(2))
case "535746":
aso.read(5)
bindata=aso.read(1)
sconv=num2str(ascb(bindata),2 ,8)
nbits=str2num(left(sconv,5),2)
sconv=mid(sconv,6)
while(len(sconv)<nbits*4)
bindata=aso.read(1)
sconv=sconv&num2str(ascb(bindata),2 ,8)
wend
ret(0)="swf"
ret(1)=int(abs(str2num(mid(sconv,1*nbits+1,nbits),2)-str2num(mid(sconv,0*nbits+1,nbits),2))/20)
ret(2)=int(abs(str2num(mid(sconv,3*nbits+1,nbits),2)-str2num(mid(sconv,2*nbits+1,nbits),2))/20)
case "ffd8ff":
do 
do: p1=binval(aso.read(1)): loop while p1=255 and not aso.eos
if p1>191 and p1<196 then exit do else aso.read(binval2(aso.read(2))-2)
do:p1=binval(aso.read(1)):loop while p1<255 and not aso.eos
loop while true
aso.read(3)
ret(0)="jpg"
ret(2)=binval2(aso.read(2))
ret(1)=binval2(aso.read(2))
case else:
if left(bin2str(bflag),2)="bm" then
aso.read(15)
ret(0)="bmp"
ret(1)=binval(aso.read(4))
ret(2)=binval(aso.read(4))
else
ret(0)=""
end if
end select
ret(3)="width=""" & ret(1) &""" height=""" & ret(2) &""""
getimagesize=ret
end function
end class
%>

将以上代码复制生成gps.asp文件，这样无组件获取图片尺寸的通用类就ok了。



2.获取图片路径

由于不只一张图片，以及图片需分类存放，我们在数据库中设计了一个存放图片相对路径的字段imgurl。我们把上传的图片都放在一个名为images的文件夹中（至于如何无组件上传图片心晴就不在多说了）。现在我们先设计一个showimg.asp页面用来显示缩略图及相关信息。具体设计如下：

图片：

图片格式：

图片尺寸：

图片大小：

点击次数：


下面，我们获取图片的绝对路径。代码如下：

<% 
'/////获取showimg.asp的绝对路径/////
dim curfile
curfile=server.mappath(request.servervariables("path_info"))

dim curfilename,filename

'/////图片相对路径（存于数据库中）
cufilename=rs("imgurl")
'/////因为showimg.asp与images在同一目录，所以我们用instrrev获取images的路径/////
filename=left(curfile,instrrev(curfile,"\"))&cufilename

'/////建立gps类实体/////
dim getpicsize
set getpicsize=new gps

set fs=server.createobject("scripting.filesystemobject")
'/////获取图片类型/////
dim picsuffixname
picsuffixname=fs.getextensionname(filename)

dim pd '//picture dimension
dim pwidth,pheight

select case picsuffixname
case "gif","bmp","jpg","png":
'/////调用gps通用类中的getimagesize函数获取图片尺寸/////
pd=getpicsize.getimagesize(filename)
pwidth=pd(1) '//获取图片宽度
pheight=pd(2) '//获取图片高度
case "swf"
pd=getpicsize.getimagesize(filename)
pwidth=pd(1) '//获取flash宽度
pheight=pd(2) '//获取flash高度
case else
end select

set fs=nothing
set getpicsize=nothing
%>



将上面的代码复制到<body>的上面就ok了！

当然，有人会说，获取路径不一定要用path_info，直接用server.mappath()不就可以了嘛，呵呵，萝卜青菜各有所爱，主要是我用path_info可以实现fso的一些功能而用server.mappath()没有搞定，所以一直使用这个。

3.定义缩略图尺寸
这部分代码就是仁者见仁，智者见智了。首先，我们需要规定缩略图显示尺寸范围，譬如：300x260，代码可以这样写：
<%
dim pxwidth,pxheight
dim pp '//proportion
if pwidth=0 or pwidth="" then
pxwidth=0
pxheight=0
else
pp=formatnumber(pwidth/pheight,2) '//长宽比
end if
if pwidth>=pheight then
if pwidth>=300 then
pxwidth=300
pxheight=formatnumber(300/pp,0)
else
pxwidth=pwidth
pxheight=pheight
end if
else
if pheight>=260 then
pxheight=260
pxwidth=formatnumber(260*pp,0)
else
pxwidth=pwidth
pxheight=pheight
end if
end if
%>
将上面的代码紧接第二步写下即可。调用时代码如下：
<img src=<%=curfilename%> border="0" width=<%=pxwidth%> height=<%=pxheight%>>
至于图片格式可以用<%=picsuffixname%>得到，图片尺寸可以写成
<% 
response.write pxwidth&"x"&pxheight
%>
图片大小可以用fso.getfilesize(filename)来实现，而点击次数可以简单地用sql语句实现，具体编码就不再累述了。

这样，一个无组件生成缩略图程序就写好了，可能有点拿来主义，不过只要大家能将方法掌握相信还是有很大提高的。