Win10通过Bat脚本自动设置以太网的IP地址

手动来回更改IP实在太麻烦，通过以下代码可自动更改，并可在1、2的基础上，无限新增待更改IP。

@echo off
rem //设置变量 
set NAME="以太网"
rem //以下属性值可以根据需要更改
set FirstADDR=172.19.9.80
set FirstMASK=255.255.255.0
set FirstGATEWAY=172.19.9.1
set FirstDNS1=202.99.160.68
set FirstDNS2=
rem //以上属性依次为IP地址、子网掩码、网关、首选DNS、备用DNS

rem //以下属性值可以根据需要更改
set SecondADDR=192.168.137.11
set SecondMASK=255.255.255.0
set SecondGATEWAY=192.168.137.1
set SecondDNS1=202.99.160.68
set SecondDNS2=
rem //以上属性依次为IP地址、子网掩码、网关、首选DNS、备用DNS


echo 当前可用操作有：
echo 1 设置为上网IP
echo 2 设置为天通IP
echo 3 退出
echo 请选择后回车：
set /p operate=
if %operate%==1 goto 1
if %operate%==2 goto 2
if %operate%==3 goto 3


:1
echo 正在设置上网IP，请稍等...
rem //可以根据你的需要更改 
echo IP地址 = %FirstADDR%
echo 掩码 = %FirstMASK%
echo 网关 = %FirstGATEWAY%
netsh interface ipv4 set address %NAME% static %FirstADDR% %FirstMASK% %FirstGATEWAY% 
echo 首选DNS = %FirstDNS1% 
netsh interface ipv4 set dns %NAME% static %FirstDNS1%
echo 备用DNS = %FirstDNS2% 
if "%FirstDNS2%"=="" (echo FirstDNS2为空) else (netsh interface ipv4 add dns %NAME% %FirstDNS2%) 
echo 上网IP已设置！
pause
goto 3


:2
echo 正在设置天通IP，请稍等...
rem //可以根据你的需要更改 
echo IP地址 = %SecondADDR%
echo 掩码 = %SecondMASK%
echo 网关 = %SecondGATEWAY%
netsh interface ipv4 set address %NAME% static %SecondADDR% %SecondMASK% %SecondGATEWAY% 
echo 首选DNS = %SecondDNS1% 
netsh interface ipv4 set dns %NAME% static %SecondDNS1%
echo 备用DNS = %SecondDNS2% 
if "%SecondDNS2%"=="" (echo SecondDNS2为空) else (netsh interface ipv4 add dns %NAME% %SecondDNS2%) 
echo 天通IP已设置！
pause
goto 3


:3
exit