VB.NET并行与分布式编程(6)-线程与内核同步[10]

E)代码分析

上节代码是最简单的异步调用代码，即调用委托的 BeginInvoke 方法来开始执行方法，在主线程上执行一些工作，然后调用委托的 EndInvoke 方法。但是EndInvoke 直到异步调用完成之后才返回，因此可能会阻止调用线程（即主线程）。

a)  声明异步方法 ，必须与后面要使用的异步调用的方法一致 

   Delegate Function myAdds(ByVal num As Integer, <Out()> ByRef threadid As Integer) As Long   

b)定义IAsyncResult 对象，用来获取异步操作的状态

Dim myasyncresult As IAsyncResult

c)定义具体方法需要异步执行，其中mythreadrun要求与前面声明的异步方法一致(参数一致)

Dim myadd As myAdds = New myAdds(AddressOf mythreadrun)

d) BeginInvoke 方法开始执行异步方法，将在NET线程池中分配线程执行,传入的参数就是mythreadrun的参数

myasyncresult = myadd.BeginInvoke(1000, threadid, Nothing, Nothing)

e)调用执行异步方法后，执行sleep，让出处理器，给工作线程执行的机会

 Thread.Sleep(0)  
 Console.WriteLine("{0},开始执行线程，主线程{1}号正在等待...", Now.ToLongTimeString, Thread.CurrentThread.ManagedThreadId)

f)等待异步调用完成，主线程才返回，同时将返回结果给resultvalue ,注意返回的就是异步方法定义的返回类型Long  

   resultvalue = myadd.EndInvoke(threadid, myasyncresult)  

g)要异步执行的方法，注意<Out()> ，它指示应将数据从被调用方封送回调用方

 

 

 

 

 Public Function mythreadrun(ByVal num As Integer, <Out()> ByRef threadid As Integer) As Long
        Dim mynum As Integer
        Dim jg As Long = 0
        threadid = Thread.CurrentThread.ManagedThreadId
        Try
            For mynum = 1 To num
                jg += mynum
                Thread.Sleep(0)
            Next
            Console.WriteLine(threadid & "号线程  " & Now.ToLongTimeString & "线程运行完毕!")
        Catch
            Console.WriteLine(threadid & "号线程  " & Now.ToLongTimeString & "线程异常终止!")
            '终止线程
            Thread.CurrentThread.Abort()
        End Try
        Return jg
    End Function

 

同时注意要直接引用OutAttribute 类所在的给定的命名空间:

Imports System.Runtime.InteropServices

 

F)我们可以继续改写这段代码，加入WaitHandle,使用 WaitHandle 等待异步调用

WaitHandle 类封装等待对共享资源的独占访问的操作系统特定的对象。IAsyncResult.AsyncWaitHandle 属性 获取用于等待异步操作完成的 WaitHandle。

a)使用 BeginInvoke 返回的 IAsyncResult 的 AsyncWaitHandle 属性获取 WaitHandle。

b)异步调用完成时会发出 WaitHandle 信号，可以通过调用 WaitOne 方法等待它。

c)使用 WaitHandle，则在异步调用完成之前或之后，在通过调用 EndInvoke 检索结果之前，还可以执行其他处。

代码如下：

Imports System
Imports System.Threading
Imports System.Runtime.InteropServices
Imports System.Diagnostics
Imports System.Diagnostics.ThreadState


Module Module1


    '定义异步方法
    Delegate Function myAdds(ByVal num As Integer, <Out()> ByRef threadid As Integer) As Long

    <MTAThread()> _
    Sub Main()




        '定义IAsyncResult
        Dim myasyncresult As IAsyncResult

        '定义需要异步执行的方法
        Dim myadd As myAdds = New myAdds(AddressOf mythreadrun)

        '定义计算结果存放处
        Dim resultvalue As Long

        '异步线程调用号
        Dim threadid As Integer



    

        '异步调用
        myasyncresult = myadd.BeginInvoke(5000, threadid, Nothing, Nothing)
        Thread.Sleep(0)
        Console.Write("{0},开始执行线程，主线程{1}号正在等待", Now.ToLongTimeString, Thread.CurrentThread.ManagedThreadId)
        '等待并执行其它代码

        While Not myasyncresult.AsyncWaitHandle.WaitOne(10)
            '执行其它代码输出一个点，同时以10毫秒为间隔等待工作线程完成
            Console.Write(".")
        End While





        '异步调用完成，返回结果
        resultvalue = myadd.EndInvoke(threadid, myasyncresult)

        '线程执行完毕   
        Console.WriteLine("{0}号线程计算结果为：{1}", threadid, resultvalue)

    End Sub
    Public Function mythreadrun(ByVal num As Integer, <Out()> ByRef threadid As Integer) As Long
        Dim mynum As Integer
        Dim jg As Long = 0
        threadid = Thread.CurrentThread.ManagedThreadId
        Try
            For mynum = 1 To num
                jg += mynum
                Thread.Sleep(2)
            Next
            Console.WriteLine(threadid & "号线程  " & Now.ToLongTimeString & "线程运行完毕!")
        Catch
            Console.WriteLine(threadid & "号线程  " & Now.ToLongTimeString & "线程异常终止!")
            '终止线程
            Thread.CurrentThread.Abort()
        End Try
        Return jg
    End Function
End Module

  上面代码中的重点是：

 

 While Not myasyncresult.AsyncWaitHandle.WaitOne(10)
            '执行其它代码输出一个点，以10毫秒为间隔等待工作线程完成
            Console.Write(".")
        End While

 

我们通过myasyncresult.AsyncWaitHandle.WaitOne(10)进行等待，

等待10毫秒工作线程仍未完成，则执行主线程工作，输出一个点 

直到完成为止，可看出以下效果: