玩转 ESP32 + Arduino (十七) deepsleep深睡眠模式
一. 关于UPL协处理器的概念
ESP32 有强大的超低功耗协处理器 (ULP co-processor)
ULP 协处理器是一个功耗极低的协处理器设备，无论主 CPU 是处于正常运行模式还是 Deep-sleep 模式，ULP 协处理器都可以独立运行。超低功耗协处理器的补充使得 ESP32 能够胜任一些对低功耗要求较高的应用场合。
ULP 协处理器的主要特性有：
采用 8 MHz 频率和 8 KB 内存
内建 ADC 和 I2C 接口
支持正常模式和 Deep-sleep 模式
可唤醒主 CPU 或向主 CPU 发送中断
能够访问主 CPU 的外围设备、内部传感器及 RTC 寄存器
鉴于以上的特性，ULP 协处理器能够在消耗较低电流的情况下，完成 ADC 采样，进行 I2C Sensor 的读写，驱动 RTC GPIO 口动作，可以在某些超低功耗场景中完全替代主 CPU。
重要的: ULP是ESP32做出优秀低功耗产品的关键
但是致命的: ULP只能用汇编????????????????
参考文档: https://blog.csdn.net/espressif/article/details/79131076
二. 理解了ULP之后, 让我们看一下ESP32的工作模式
可以看到ESP32在深睡眠模式下可以启动或停止ULP协处理器
三. ESP32 deepsleep模式唤醒方式及关键API
唤醒方式:
- 定时器唤醒
- 两种引脚唤醒方式
- 触摸按键唤醒
- ULP唤醒
1. 开始进入深睡眠: esp_deep_sleep_start();
esp_deep_sleep_start();2. 获取esp32被唤醒的原因 esp_deep_sleep_get_wakeup_cause();
这是一个ESP-IDF的原生方法, 如果我们想用, 需要引入头文件
#include <esp_sleep.h>注意:#include <esp_deep_sleep.h>即将被弃用, 所以不要再用这个头文件了
Serial.println(esp_deep_sleep_get_wakeup_cause());返回: 被唤醒原因码:
| 原因码 | 对应原因 | 说明 |
|---|---|---|
| 0 | ESP_SLEEP_WAKEUP_UNDEFINED | 没有定义被唤醒的原因(第一次启动时会报) |
| 2 | ESP_SLEEP_WAKEUP_EXT0 | 被RTC_GPIO唤醒 |
| 3 | ESP_SLEEP_WAKEUP_EXT1 | 被RTC_CNTL引脚集合的变化唤醒 |
| 4 | ESP_SLEEP_WAKEUP_TIMER | 被ESP的定时器唤醒 |
| 5 | ESP_SLEEP_WAKEUP_TOUCHPAD | 被触摸唤醒 |
| 6 | ESP_SLEEP_WAKEUP_ULP | 被ULP唤醒 |
| 7 | ESP_SLEEP_WAKEUP_GPIO | 被GPIO唤醒(仅限轻睡眠模式light sleep) |
| 8 | ESP_SLEEP_WAKEUP_UART | 被串口唤醒(仅限轻睡眠模式light sleep) |
3. 设置具体的唤醒源请看下面的相关章节
四. RTC memory
ESP32有8KB的RTC存储器
在RTC memory里的变量不会因为deepsleep被清除, 创建方法:
RTC_DATA_ATTR int bootCount = 0;注意, RTC memory会被硬件reset清除
五. 进入休眠后定时器唤醒
esp_sleep_enable_timer_wakeup(20000000);参数:
- 定时时间,单位μ秒, 类型uint64_t, 所以定时时间要在584942年以内????????????
例子:
#include <Arduino.h>
#include <esp_sleep.h>
RTC_DATA_ATTR int bootCount = 0;
void setup()
{
Serial.begin(115200);
Serial.printf("ESP32 is restart now! It's the %d time\r\n", ++bootCount);
delay(5000);
esp_sleep_enable_timer_wakeup(20000000);
Serial.println(esp_sleep_get_wakeup_cause());
}
void loop()
{
Serial.println("ESP32 will sleep now!");
delay(100);
esp_deep_sleep_start();
}六. 进入休眠后被RTC_GPIO唤醒 (引脚唤醒方式一)
首先,并不是每个GPIO都是RTC_GPIO, 详见下表
注意: 我们填写的GPIO引脚号是真正的引脚号 不是其RTC_GPIO编号
esp_sleep_enable_ext0_wakeup(GPIO_NUM_35, 0);#include <Arduino.h>
#include <esp_sleep.h>
RTC_DATA_ATTR int bootCount = 0;
void setup()
{
Serial.begin(115200);
Serial.printf("ESP32 is restart now! It's the %d time\r\n", ++bootCount);
esp_sleep_enable_ext0_wakeup(GPIO_NUM_35, 0);
Serial.printf("the wakeup reason is :%d\r\n", esp_sleep_get_wakeup_cause());
}
void loop()
{
delay(3000);
Serial.println("ESP32 will sleep now!");
delay(100);
esp_deep_sleep_start();
}七. 进入休眠后被RTC_CNTL唤醒 (引脚唤醒方式二)
思考一个问题, 如果我们有8个GPIO引脚想唤醒ESP32, 难道要用上一节的方法操作8遍吗?
当然不是, 我们可以直接操作引脚集合, (我们用一个mask片选想操作的引脚,然后这些引脚都具有了唤醒ESP32的能力)
我们可以设置这些引脚是 每个都能触发(每个葫芦娃都能自己去救爷爷), 还是一起共同发力才能触发(集齐七龙珠??)
esp_sleep_enable_ext1_wakeup(uint64_t mask, esp_sleep_ext1_wakeup_mode_t mode);参数:
- mask :
如: 我们想让 32 33 35 39触发, 这样计算mask
注意: 我们不要使用 37 38
- mode: 触发方式 可选:
- ESP_EXT1_WAKEUP_ALL_LOW : 全都置低时触发唤醒
- ESP_EXT1_WAKEUP_ANY_HIGH : 任意置高时触发唤醒
八. 进入休眠后被触摸按键唤醒
值得注意的是,
- 触摸按键唤醒所需deepsleep电流要大于 按键和定时器
- 必须写触摸回调函数, 否则无用
#include <Arduino.h>
#include <esp_sleep.h>
RTC_DATA_ATTR int bootCount = 0;
RTC_DATA_ATTR int BTN_Pin_BITMASK = 0;
void callbackPin2()
{
Serial.println("T2 weak ESP32 up");
}
void setup()
{
Serial.begin(115200);
Serial.printf("ESP32 is restart now! It's the %d time\r\n", ++bootCount);
esp_sleep_enable_touchpad_wakeup();
Serial.printf("the wakeup reason is :%d\r\n", esp_sleep_get_wakeup_cause());
touchAttachInterrupt(2,callbackPin2,40);
}
void loop()
{
delay(3000);
Serial.println("ESP32 will sleep now!");
delay(100);
esp_deep_sleep_start();
}九. 被ULP唤醒
这个要做一个专门的ULP专题
本文地址：https://blog.csdn.net/finedayforu/article/details/108547038