一个32位操作系统的实现1——MBR引导
程序员文章站
2022-07-08 07:58:26
...
近日，看到朋友圈的几位大佬都在研究操作系统，正好闲来无事，也花了点时间研究了一番，发现还蛮有趣的，于是乎就有了该系列文章，以记录分享研究心得~
1、MBR引导程序
开发操作系统的第一步，自然是实现MBR引导，此刻我们面对的是一部仅运行BIOS(Basic Input Output System基本输入输出系统)的裸机，通电开机以后，BIOS程序会加载磁盘或者软盘等存储设备，一旦检测到磁盘或软盘的第0磁头第0磁道第1扇区(每个扇区512字节)的末尾2个字节内容为0x55、0xAA，BIOS则认为它是一个MBR引导扇区(512字节)，然后将该引导扇区的全部内容(也就是512字节)加载到内存中0x7c00处然后执行(为什么是0x7c00处，这个是因为当年留下来的设计，一直沿用至今而已，无特殊含义)，作为一个仅512字节的程序，引导程序所能做出的工作是有限的，而在进入操作系统之前我们还需要做很多工作，比如设置VGA图形模式，再比如由实模式跳转到保护模式、加载内核文件等等工作，这些工作对于仅仅512字节的MBR程序而言显然有点无能为力，就如同火箭的一级助推，要想飞出地球，我们还需要二级助推，这二级助推就是loader加载程序。所以，我们暂且可以认为MBR引导程序的功能只有一个，那就是搜索磁盘下的loader程序，然后加载到内存并执行。
2、如何实现MBR引导程序
通过前面的描述，我们的工作目标已经变得很明确，我们需要实现一个大小为512字节的程序(暂且给它取名boot.bin吧)，该程序会搜索磁盘或软盘寻找loader加载程序(暂且给它取名loader.bin)，如果该程序文件存在就加载，如果不存在就在屏幕上显示一个提示字符，boot.bin代码如下:
1、MBR引导程序
开发操作系统的第一步，自然是实现MBR引导，此刻我们面对的是一部仅运行BIOS(Basic Input Output System基本输入输出系统)的裸机，通电开机以后，BIOS程序会加载磁盘或者软盘等存储设备，一旦检测到磁盘或软盘的第0磁头第0磁道第1扇区(每个扇区512字节)的末尾2个字节内容为0x55、0xAA，BIOS则认为它是一个MBR引导扇区(512字节)，然后将该引导扇区的全部内容(也就是512字节)加载到内存中0x7c00处然后执行(为什么是0x7c00处，这个是因为当年留下来的设计，一直沿用至今而已，无特殊含义)，作为一个仅512字节的程序，引导程序所能做出的工作是有限的，而在进入操作系统之前我们还需要做很多工作，比如设置VGA图形模式，再比如由实模式跳转到保护模式、加载内核文件等等工作，这些工作对于仅仅512字节的MBR程序而言显然有点无能为力，就如同火箭的一级助推，要想飞出地球，我们还需要二级助推，这二级助推就是loader加载程序。所以，我们暂且可以认为MBR引导程序的功能只有一个，那就是搜索磁盘下的loader程序，然后加载到内存并执行。
2、如何实现MBR引导程序
通过前面的描述，我们的工作目标已经变得很明确，我们需要实现一个大小为512字节的程序(暂且给它取名boot.bin吧)，该程序会搜索磁盘或软盘寻找loader加载程序(暂且给它取名loader.bin)，如果该程序文件存在就加载，如果不存在就在屏幕上显示一个提示字符，boot.bin代码如下:
org 07c00h
BaseOfStack equ 07c00h
BaseOfLoader equ 09000h ; LOADER.BIN 被加载到的位置 ---- 段地址
OffsetOfLoader equ 0100h ; LOADER.BIN 被加载到的位置 ---- 偏移地址
RootDirSectors equ 14 ; 根目录占用空间
SectorNoOfRootDirectory equ 19 ; Root Directory 的第一个扇区号
SectorNoOfFAT1 equ 1 ; FAT1 的第一个扇区号 = BPB_RsvdSecCnt
DeltaSectorNo equ 17 ; DeltaSectorNo = BPB_RsvdSecCnt + (BPB_NumFATs * FATSz) - 2
jmp short LABEL_START;
nop;
BS_OEMName DB 'CHENYANG' ; OEM String, 必须 8 个字节
BPB_BytsPerSec DW 512 ; 每扇区字节数
BPB_SecPerClus DB 1 ; 每簇多少扇区
BPB_RsvdSecCnt DW 1 ; Boot 记录占用多少扇区
BPB_NumFATs DB 2 ; 共有多少 FAT 表
BPB_RootEntCnt DW 224 ; 根目录文件数最大值
BPB_TotSec16 DW 2880 ; 逻辑扇区总数
BPB_Media DB 0xF0 ; 媒体描述符
BPB_FATSz16 DW 9 ; 每FAT扇区数
BPB_SecPerTrk DW 18 ; 每磁道扇区数
BPB_NumHeads DW 2 ; 磁头数(面数)
BPB_HiddSec DD 0 ; 隐藏扇区数
BPB_TotSec32 DD 0 ; 如果 wTotalSectorCount 是 0 由这个值记录扇区数
BS_DrvNum DB 0 ; 中断 13 的驱动器号
BS_Reserved1 DB 0 ; 未使用
BS_BootSig DB 29h ; 扩展引导标记 (29h)
BS_VolID DD 0 ; 卷序列号
BS_VolLab DB 'chenyangos '; 卷标, 必须 11 个字节
BS_FileSysType DB 'FAT12 ' ; 文件系统类型, 必须 8个字节
LABEL_START:
;初始化寄存器
mov ax, cs
mov ds, ax
mov es, ax
mov ss, ax
mov sp, BaseOfStack
;清屏
mov ax, 0600h ; AH = 6, AL = 0h
mov bx, 0700h ; 黑底白字(BL = 07h)
mov cx, 0 ; 左上角: (0, 0)
mov dx, 0184fh ; 右下角: (80, 50)
int 10h ; int 10h
mov dh, 0 ; "start boot"
call DispStr ; 显示字符串
;软盘复位
xor ah, ah ;
xor dl, dl ;
int 13h ;
;下面在 A 盘的根目录寻找 LOADER.BIN
mov word [wSectorNo], SectorNoOfRootDirectory
LABEL_SEARCH_IN_ROOT_DIR_BEGIN:
cmp word [wRootDirSizeForLoop], 0 ; ┓
jz LABEL_NO_LOADERBIN ; ┣ 判断根目录区是不是已经读完
dec word [wRootDirSizeForLoop] ; ┛ 如果读完表示没有找到 LOADER.BIN
mov ax, BaseOfLoader
mov es, ax
mov bx, OffsetOfLoader
mov ax, [wSectorNo]
mov cl, 1
call ReadSector
mov si, LoaderFileName ; ds:si -> "LOADER BIN"
mov di, OffsetOfLoader ; es:di -> BaseOfLoader:0100 = BaseOfLoader*10h+100
cld
mov dx, 10h
LABEL_SEARCH_FOR_LOADERBIN:
cmp dx, 0 ; ┓循环次数控制,
jz LABEL_GOTO_NEXT_SECTOR_IN_ROOT_DIR ; ┣如果已经读完了一个 Sector,
dec dx ; ┛就跳到下一个 Sector
mov cx, 11
LABEL_CMP_FILENAME:
cmp cx, 0
jz LABEL_FILENAME_FOUND ; 如果比较了 11 个字符都相等, 表示找到
dec cx
lodsb
cmp al, byte [es:di]
jz LABEL_GO_ON
jmp LABEL_DIFFERENT ; 只要发现不一样的字符就表明不是我们要找的LOADER.BIN
LABEL_GO_ON:
inc di
jmp LABEL_CMP_FILENAME ; 继续循环
LABEL_DIFFERENT:
and di, 0FFE0h ;else ┓di &= E0 为了让它指向本条目开头
add di, 20h ; ┃
mov si, LoaderFileName ; ┣ di += 20h 下一个目录条目
jmp LABEL_SEARCH_FOR_LOADERBIN;┛
LABEL_GOTO_NEXT_SECTOR_IN_ROOT_DIR:
add word [wSectorNo], 1
jmp LABEL_SEARCH_IN_ROOT_DIR_BEGIN
LABEL_NO_LOADERBIN:
mov dh, 2 ; "No LOADER."
call DispStr ; 显示字符串
jmp $
LABEL_FILENAME_FOUND: ; 找到 LOADER.BIN 后便来到这里继续
mov ax, RootDirSectors
and di, 0FFE0h ; di -> 当前条目的开始
add di, 01Ah ; di -> 首 Sector
mov cx, word [es:di]
push cx ; 保存此 Sector 在 FAT 中的序号
add cx, ax
add cx, DeltaSectorNo ; 这句完成时 cl 里面变成 LOADER.BIN 的起始扇区号 (从 0 开始数的序号)
mov ax, BaseOfLoader
mov es, ax ; es <- BaseOfLoader
mov bx, OffsetOfLoader
mov ax, cx ; ax <- Sector 号
LABEL_GOON_LOADING_FILE:
push ax ; ┓
push bx ; ┃
mov ah, 0Eh ; ┃ 每读一个扇区就在 "Booting " 后面打一个点, 形成这样的效果:
mov al, '.' ; ┃
mov bl, 0Fh ; ┃ Booting ......
int 10h ; ┃
pop bx ; ┃
pop ax ; ┛
mov cl, 1
call ReadSector
pop ax ; 取出此 Sector 在 FAT 中的序号
call GetFATEntry
cmp ax, 0FFFh
jz LABEL_FILE_LOADED
push ax ; 保存 Sector 在 FAT 中的序号
mov dx, RootDirSectors
add ax, dx
add ax, DeltaSectorNo
add bx, [BPB_BytsPerSec]
jmp LABEL_GOON_LOADING_FILE
LABEL_FILE_LOADED:
mov dh, 1 ; "Ready."
call DispStr ; 显示字符串
jmp BaseOfLoader:OffsetOfLoader ; 这一句正式跳转到已加载到内存中的 LOADER.BIN 的开始处
;============================================================================
;变量和字符
;============================================================================
wRootDirSizeForLoop dw RootDirSectors ; Root Directory 占用的扇区数, 在循环中会递减至零.
wSectorNo dw 0 ; 要读取的扇区号
bOdd db 0 ; 奇数还是偶数
LoaderFileName db "LOADER BIN", 0; LOADER.BIN 之文件名
MessageLength equ 10
BootMessage: db "start boot"; 10字节, 不够则用空格补齐. 序号 0
Message1 db "Ready. "; 10字节, 不够则用空格补齐. 序号 1
Message2 db "no loader "; 10字节, 不够则用空格补齐. 序号 2
;----------------------------------------------------------------------------
; 函数名: DispStr
; 作用:显示一个字符串, 函数开始时 dh 中应该是字符串序号(0-based)
;----------------------------------------------------------------------------
DispStr:
mov ax, MessageLength
mul dh
add ax, BootMessage
mov bp, ax ; ┓
mov ax, ds ; ┣ ES:BP = 串地址
mov es, ax ; ┛
mov cx, MessageLength ; CX = 串长度
mov ax, 01301h ; AH = 13, AL = 01h
mov bx, 0007h ; 页号为0(BH = 0) 黑底白字(BL = 07h)
mov dl, 0
int 10h ; int 10h
ret
;----------------------------------------------------------------------------
; 函数名: ReadSector
; 作用：从第 ax 个 Sector 开始, 将 cl 个 Sector 读入 es:bx 中
;----------------------------------------------------------------------------
ReadSector:
push bp
mov bp, sp
sub esp, 2 ; 辟出两个字节的堆栈区域保存要读的扇区数: byte [bp-2]
mov byte [bp-2], cl
push bx ; 保存 bx
mov bl, [BPB_SecPerTrk] ; bl: 除数
div bl ; y 在 al 中, z 在 ah 中
inc ah ; z ++
mov cl, ah ; cl <- 起始扇区号
mov dh, al ; dh <- y
shr al, 1 ; y >> 1 (其实是 y/BPB_NumHeads, 这里BPB_NumHeads=2)
mov ch, al ; ch <- 柱面号
and dh, 1 ; dh & 1 = 磁头号
pop bx ; 恢复 bx, "柱面号, 起始扇区, 磁头号" 全部得到
mov dl, [BS_DrvNum] ; 驱动器号 (0 表示 A 盘)
.GoOnReading:
mov ah, 2 ; 读
mov al, byte [bp-2] ; 读 al 个扇区
int 13h
jc .GoOnReading ; 如果读取错误 CF 会被置为 1, 这时就不停地读, 直到正确为止
add esp, 2
pop bp
ret
;----------------------------------------------------------------------------
; 函数名: GetFATEntry
; 作用: 找到序号为 ax 的 Sector 在 FAT 中的条目, 结果放在 ax 中
;----------------------------------------------------------------------------
GetFATEntry:
push es
push bx
push ax
mov ax, BaseOfLoader; ┓
sub ax, 0100h ; ┣ 在 BaseOfLoader 后面留出 4K 空间用于存放 FAT
mov es, ax ; ┛
pop ax
mov byte [bOdd], 0
mov bx, 3
mul bx ; dx:ax = ax * 3
mov bx, 2
div bx ; dx:ax / 2 ==> ax <- 商, dx <- 余数
cmp dx, 0
jz LABEL_EVEN
mov byte [bOdd], 1
LABEL_EVEN:
xor dx, dx
mov bx, [BPB_BytsPerSec]
div bx
push dx
mov bx, 0
add ax, SectorNoOfFAT1
mov cl, 2
call ReadSector
pop dx
add bx, dx
mov ax, [es:bx]
cmp byte [bOdd], 1
jnz LABEL_EVEN_2
shr ax, 4
LABEL_EVEN_2:
and ax, 0FFFh
LABEL_GET_FAT_ENRY_OK:
pop bx
pop es
ret
;----------------------------------------------------------------------------
times 510-($-$$) db 0 ; 填充剩下的空间，使生成的二进制代码恰好为512字节
dw 0xaa55 ; 结束标志
上一篇： jAVA